buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.3.1'
        classpath 'org.ajoberstar:grgit:1.4.1'
    }
}
apply plugin: 'com.android.application'

dependencies {
    compile 'com.android.support:appcompat-v7:23.1.1'
    compile 'com.android.support:design:23.1.1'
    compile 'com.android.support:preference-v7:23.1.1'
    compile 'com.android.support:preference-v14:23.1.1'
}

ext {
  git = org.ajoberstar.grgit.Grgit.open(file('.'))
  gitVersionCode = git.log().size()
  gitVersionName = "${git.describe()}"
}

android {
    compileSdkVersion 'android-23'
    buildToolsVersion '23.0.1'

    defaultConfig {
        minSdkVersion 11
        targetSdkVersion 23

        versionCode gitVersionCode
        versionName gitVersionName
        resValue "string", "app_name", "SaveMySugar"
        setProperty("archivesBaseName", "SaveMySugar-$versionName")
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFile getDefaultProguardFile('proguard-android.txt')
        }
    }
}

allprojects {
    tasks.withType(JavaCompile) {
        options.compilerArgs << "-Xlint:deprecation"
        options.compilerArgs << "-Xlint:unchecked"
    }
}