examples/CMakeLists.txt

   1 include(CheckSymbolExists)
   2 add_definitions("-D_POSIX_C_SOURCE=2") # for getopt()
   3 add_definitions("-D_POSIX_SOURCE") # for sigaction
   4 add_definitions("-D_BSD_SOURCE") # for strdup
   5
   6 include_directories(${CMAKE_SOURCE_DIR}/src/)
   7
   8 # Build a test app that sends a single picture
   9 option(BUILD_PICOPROJ "Build a test app that sends a single picture" TRUE)
  10 if(BUILD_PICOPROJ)
  11   add_executable(picoproj picoproj.c)
  12   target_link_libraries(picoproj am7xxx)
  13   install(TARGETS picoproj
  14     DESTINATION "${CMAKE_INSTALL_PREFIX}/bin")
  15 endif()
  16
  17 # Build a more complete example
  18 option(BUILD_AM7XXX-PLAY "Build a more complete example: am7xxx-play" TRUE)
  19 if(BUILD_AM7XXX-PLAY)
  20   find_package(FFmpeg REQUIRED)
  21   set(CMAKE_REQUIRED_LIBRARIES ${FFMPEG_LIBRARIES})
  22   set(CMAKE_REQUIRED_INCLUDES ${FFMPEG_LIBAVFORMAT_INCLUDE_DIRS})
  23   check_symbol_exists(avformat_open_input
  24     "${FFMPEG_LIBAVFORMAT_INCLUDE_DIRS}/libavformat/avformat.h"
  25     HAVE_AVFORMAT_OPEN_INPUT)
  26   if(NOT HAVE_AVFORMAT_OPEN_INPUT)
  27     message(FATAL_ERROR
  28       "Function avformat_open_input missing. Please use a newer FFmpeg release.")
  29   endif()
  30
  31   include_directories(${FFMPEG_LIBAVDEVICE_INCLUDE_DIRS})
  32   include_directories(${FFMPEG_LIBAVFORMAT_INCLUDE_DIRS})
  33   include_directories(${FFMPEG_LIBSWSCALE_INCLUDE_DIRS})
  34
  35   set(CMAKE_REQUIRED_DEFINITIONS -D_POSIX_SOURCE)
  36   check_symbol_exists(sigaction "signal.h" HAVE_SIGACTION)
  37   if (HAVE_SIGACTION)
  38     add_definitions("-DHAVE_SIGACTION")
  39   endif()
  40
  41   check_symbol_exists(strtok_r "string.h" HAVE_STRTOK_R)
  42   if (HAVE_STRTOK_R)
  43     add_definitions("-DHAVE_STRTOK_R")
  44   endif()
  45   set(CMAKE_REQUIRED_DEFINITIONS)
  46
  47   # xcb is used to retrieve the full screen dimensions when using x11grab
  48   # as input format
  49   find_package(XCB)
  50   if (XCB_FOUND)
  51     add_definitions("${LIBXCB_DEFINITIONS} -DHAVE_XCB")
  52     include_directories(${LIBXCB_INCLUDE_DIRS})
  53     set(OPTIONAL_LIBRARIES ${LIBXCB_LIBRARIES})
  54   endif()
  55
  56   add_executable(am7xxx-play am7xxx-play.c)
  57
  58   target_link_libraries(am7xxx-play am7xxx
  59     ${FFMPEG_LIBRARIES}
  60     ${FFMPEG_LIBSWSCALE_LIBRARIES}
  61     ${OPTIONAL_LIBRARIES})
  62   install(TARGETS am7xxx-play
  63     DESTINATION "${CMAKE_INSTALL_PREFIX}/bin")
  64 endif()
  65
  66 # Build a simple usb-modeswitch clone for am7xxx devices
  67 option(BUILD_am7xxx-modeswitch "Build a simple usbmode-switch clone for am7xxx devices" TRUE)
  68 if(BUILD_am7xxx-modeswitch)
  69
  70   find_package(libusb-1.0 REQUIRED)
  71   include_directories(${LIBUSB_1_INCLUDE_DIRS})
  72
  73   add_executable(am7xxx-modeswitch am7xxx-modeswitch.c)
  74   target_link_libraries(am7xxx-modeswitch ${LIBUSB_1_LIBRARIES})
  75   install(TARGETS am7xxx-modeswitch
  76     DESTINATION "${CMAKE_INSTALL_PREFIX}/bin")
  77 endif()
  78