src/rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     exclude-result-prefixes="php">
  25
  26     <xsl:param name="generate-enclosure"/>
  27     <xsl:param name="show-usernames"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:variable name="user-name" select="//ProfilePage/graphql/user/username"/>
  36
  37     <!--
  38          NOTE: some users do not specify the full name.
  39
  40          Remember to handle this case when using it and fall-back to the plain
  41          user name when appropriate.
  42     -->
  43     <xsl:variable name="full-name" select="//ProfilePage/graphql/user/full_name"/>
  44
  45     <xsl:variable name="location-name" select="//LocationsPage/graphql/location/name"/>
  46
  47     <xsl:variable name="hashtag-name" select="//TagPage/graphql/hashtag/name"/>
  48
  49     <xsl:variable name="screen-name">
  50         <xsl:choose>
  51             <xsl:when test="$location-name != ''">
  52                 <xsl:value-of select="$location-name"/>
  53             </xsl:when>
  54             <xsl:when test="$hashtag-name != ''">
  55                 <xsl:value-of select="$hashtag-name"/>
  56             </xsl:when>
  57             <xsl:when test="$full-name != ''">
  58                 <xsl:value-of select="$full-name"/>
  59             </xsl:when>
  60             <xsl:otherwise>
  61                 <xsl:value-of select="$user-name"/>
  62             </xsl:otherwise>
  63         </xsl:choose>
  64     </xsl:variable>
  65
  66     <xsl:template match="//edges/node">
  67         <xsl:variable name="item-content-image" select="./display_url"/>
  68         <xsl:variable name="item-content-caption" select="./edge_media_to_caption/edges/node/text"/>
  69         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./shortcode, '/')"/>
  70         <item>
  71             <title>
  72                 <xsl:variable name="title-length" select="140"/>
  73                 <xsl:variable name="item-content-title">
  74                     <xsl:if test="$show-usernames = 1">
  75                         <xsl:value-of select="concat($screen-name, ': ')"/>
  76                     </xsl:if>
  77                     <xsl:value-of select="normalize-space($item-content-caption)"/>
  78                 </xsl:variable>
  79                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  80                 <xsl:choose>
  81                     <xsl:when test="string-length($item-content-title) > $title-length">
  82                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  83                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  84                         <xsl:text>...</xsl:text>
  85                     </xsl:when>
  86                     <xsl:otherwise>
  87                         <xsl:value-of select="$item-content-title"/>
  88                     </xsl:otherwise>
  89                 </xsl:choose>
  90             </title>
  91             <link>
  92                 <xsl:value-of select="$item-permalink"/>
  93             </link>
  94             <guid>
  95                 <xsl:value-of select="$item-permalink"/>
  96             </guid>
  97             <pubDate>
  98                 <xsl:variable name="timestamp" select="./taken_at_timestamp"/>
  99                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
 100             </pubDate>
 101             <description>
 102                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 103                 <p>
 104                     <xsl:if test="./is_video/text() = 1">
 105                         (Video)
 106                     </xsl:if>
 107                     <xsl:value-of select="$item-content-caption"/>
 108                 </p><br />
 109                 <a href="{$item-permalink}"><img src="{$item-content-image}" style="max-width: 100%"/></a>
 110                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 111             </description>
 112             <xsl:if test="$generate-enclosure = 1">
 113                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $item-content-image)"/>
 114             </xsl:if>
 115         </item>
 116     </xsl:template>
 117
 118     <xsl:template match="/">
 119
 120         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 121         <xsl:variable name="channel-link">
 122             <xsl:choose>
 123                 <xsl:when test="$location-name != ''">
 124                     <xsl:variable name="location-id" select="//LocationsPage/graphql/location/id"/>
 125                     <xsl:value-of select="concat($BaseURL, '/explore/locations/', $location-id)"/>
 126                 </xsl:when>
 127                 <xsl:when test="$hashtag-name != ''">
 128                     <xsl:value-of select="concat($BaseURL, '/explore/tags/', $hashtag-name)"/>
 129                 </xsl:when>
 130                 <xsl:otherwise>
 131                     <xsl:value-of select="concat($BaseURL, '/', $user-name)"/>
 132                 </xsl:otherwise>
 133             </xsl:choose>
 134         </xsl:variable>
 135         <xsl:variable name="channel-image" select="//profile_pic_url"/>
 136
 137         <rss version="2.0">
 138             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 139             <channel>
 140                 <generator>Tweeper</generator>
 141                 <title>
 142                     <xsl:value-of select="$channel-title"/>
 143                 </title>
 144                 <link>
 145                     <xsl:value-of select="$channel-link"/>
 146                 </link>
 147                 <description>
 148                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 149                     <xsl:choose>
 150                         <xsl:when test="$location-name != ''">
 151                             <xsl:variable name="location-latitude" select="//LocationsPage/graphql/location/lat"/>
 152                             <xsl:variable name="location-longitude" select="//LocationsPage/graphql/location/lng"/>
 153                             <xsl:value-of select="concat($location-name, ' (', $location-latitude, ', ', $location-longitude, ')')"/>
 154                         </xsl:when>
 155                         <xsl:when test="$hashtag-name != ''">
 156                             <xsl:value-of select="concat('#', $hashtag-name)"/>
 157                         </xsl:when>
 158                         <xsl:otherwise>
 159                             <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 160                             <xsl:variable name="external-url" select="//user/external_url"/>
 161                             <xsl:if test="$external-url != ''">
 162                                 <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 163                             </xsl:if>
 164                         </xsl:otherwise>
 165                     </xsl:choose>
 166                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 167                 </description>
 168                 <xsl:if test="$channel-image != ''">
 169                     <image>
 170                         <title>
 171                             <xsl:value-of select="$channel-title"/>
 172                         </title>
 173                         <link>
 174                             <xsl:value-of select="$channel-link"/>
 175                         </link>
 176                         <url>
 177                             <xsl:value-of select="$channel-image"/>
 178                         </url>
 179                     </image>
 180                 </xsl:if>
 181                 <xsl:apply-templates select="//ProfilePage/graphql/user/edge_owner_to_timeline_media/edges/node|//LocationsPage/graphql/location/edge_location_to_media/edges/node|//TagPage/graphql/hashtag/edge_hashtag_to_media/edges/node"/>
 182             </channel>
 183         </rss>
 184     </xsl:template>
 185 </xsl:stylesheet>