rss_converter_twitter.com.xsl

   1 <!--
   2   Stylesheet to convert Twitter user timelines to RSS.
   3
   4   Copyright (C) 2013  Antonio Ospite <ospite@studenti.unina.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php">
  25
  26     <xsl:output method="xml" indent="yes"/>
  27
  28     <xsl:variable name="twitterBaseURL">
  29         <xsl:text>https://twitter.com</xsl:text>
  30     </xsl:variable>
  31
  32     <xsl:template match="a[@data-expanded-url]">
  33         <xsl:value-of disable-output-escaping="yes" select="php:function('generate_enclosure', string(./@data-expanded-url))"/>
  34     </xsl:template>
  35
  36     <xsl:variable name="screen-name" select="//div[@class='profile-card-inner']/@data-screen-name"/>
  37
  38     <xsl:template match="//div[@id='timeline']//ol[@id='stream-items-id']//li[@data-item-type='tweet']">
  39         <xsl:variable name="tweet-text" select=".//p[@class='js-tweet-text tweet-text']"/>
  40         <item>
  41             <title>
  42                 <xsl:value-of select="concat($screen-name, ': ', $tweet-text)"/>
  43             </title>
  44             <link>
  45                 <xsl:value-of select="concat($twitterBaseURL, .//a[@class='details with-icn js-details']/@href)"/>
  46             </link>
  47             <pubDate>
  48                 <xsl:value-of select="php:functionString('epoch_to_gmdate', .//small[@class='time']//span/@data-time)"/>
  49             </pubDate>
  50             <description>
  51                 <xsl:value-of select="concat($screen-name, ': ')"/>
  52                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  53                 <xsl:copy-of select="$tweet-text/node()"/>
  54                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  55             </description>
  56             <xsl:apply-templates select="$tweet-text//a[@data-expanded-url]"/>
  57         </item>
  58     </xsl:template>
  59
  60     <xsl:template match="/">
  61
  62         <rss version="2.0">
  63             <channel>
  64                 <generator>Tweeper</generator>
  65                 <title>
  66                     <xsl:text>Twitter / </xsl:text><xsl:value-of select="$screen-name"/>
  67                 </title>
  68                 <link>
  69                     <xsl:value-of select="//link[@rel='canonical']/@href"/>
  70                 </link>
  71                 <description>
  72                     <xsl:value-of select="//meta[@name='description']/@content"/>
  73                 </description>
  74                 <image>
  75                     <url>
  76                         <xsl:value-of select="//a[@class='profile-picture media-thumbnail']/@href"/>
  77                     </url>
  78                 </image>
  79                 <xsl:apply-templates select="//div[@id='timeline']//ol[@id='stream-items-id']//li[@data-item-type='tweet']"/>
  80             </channel>
  81         </rss>
  82     </xsl:template>
  83 </xsl:stylesheet>