src/rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:variable name="user-name" select="//ProfilePage/graphql/user/username"/>
  36
  37     <!--
  38          NOTE: some users do not specify the full name.
  39
  40          Remember to handle this case when using it and fall-back to the plain
  41          user name when appropriate.
  42     -->
  43     <xsl:variable name="full-name" select="//ProfilePage/graphql/user/full_name"/>
  44
  45     <xsl:variable name="location-name" select="//LocationsPage/graphql/location/name"/>
  46
  47     <xsl:variable name="screen-name">
  48         <xsl:choose>
  49             <xsl:when test="$location-name != ''">
  50                 <xsl:value-of select="$location-name"/>
  51             </xsl:when>
  52             <xsl:when test="$full-name != ''">
  53                 <xsl:value-of select="$full-name"/>
  54             </xsl:when>
  55             <xsl:otherwise>
  56                 <xsl:value-of select="$user-name"/>
  57             </xsl:otherwise>
  58         </xsl:choose>
  59     </xsl:variable>
  60
  61     <xsl:template match="//edges/node">
  62         <xsl:variable name="item-content-image" select="./display_url"/>
  63         <xsl:variable name="item-content-caption" select="./edge_media_to_caption/edges/node/text"/>
  64         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./shortcode, '/')"/>
  65         <item>
  66             <title>
  67                 <xsl:variable name="title-length" select="140"/>
  68                 <xsl:variable name="item-content-title" select="normalize-space(concat($screen-name, ': ', $item-content-caption))"/>
  69                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  70                 <xsl:choose>
  71                     <xsl:when test="string-length($item-content-title) > $title-length">
  72                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  73                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  74                         <xsl:text>...</xsl:text>
  75                     </xsl:when>
  76                     <xsl:otherwise>
  77                         <xsl:value-of select="$item-content-title"/>
  78                     </xsl:otherwise>
  79                 </xsl:choose>
  80             </title>
  81             <link>
  82                 <xsl:value-of select="$item-permalink"/>
  83             </link>
  84             <guid>
  85                 <xsl:value-of select="$item-permalink"/>
  86             </guid>
  87             <pubDate>
  88                 <xsl:variable name="timestamp" select="./taken_at_timestamp"/>
  89                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
  90             </pubDate>
  91             <description>
  92                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  93                 <p>
  94                     <xsl:if test="./is_video/text() = 1">
  95                         (Video)
  96                     </xsl:if>
  97                     <xsl:value-of select="$item-content-caption"/>
  98                 </p><br />
  99                 <a href="{$item-permalink}"><img src="{$item-content-image}" style="max-width: 100%"/></a>
 100                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 101             </description>
 102             <xsl:if test="$generate-enclosure = 1">
 103                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $item-content-image)"/>
 104             </xsl:if>
 105         </item>
 106     </xsl:template>
 107
 108     <xsl:template match="/">
 109
 110         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 111         <xsl:variable name="channel-link">
 112             <xsl:choose>
 113                 <xsl:when test="$location-name != ''">
 114                     <xsl:variable name="location-id" select="//LocationsPage/graphql/location/id"/>
 115                     <xsl:value-of select="concat($BaseURL, '/explore/locations/', $location-id)"/>
 116                 </xsl:when>
 117                 <xsl:otherwise>
 118                     <xsl:value-of select="concat($BaseURL, '/', $user-name)"/>
 119                 </xsl:otherwise>
 120             </xsl:choose>
 121         </xsl:variable>
 122         <xsl:variable name="channel-image" select="//ProfilePage/graphql/user/profile_pic_url"/>
 123
 124         <rss version="2.0">
 125             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 126             <channel>
 127                 <generator>Tweeper</generator>
 128                 <title>
 129                     <xsl:value-of select="$channel-title"/>
 130                 </title>
 131                 <link>
 132                     <xsl:value-of select="$channel-link"/>
 133                 </link>
 134                 <description>
 135                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 136                     <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 137                     <xsl:if test="$location-name != ''">
 138                         <xsl:variable name="location-latitude" select="//LocationsPage/graphql/location/lat"/>
 139                         <xsl:variable name="location-longitude" select="//LocationsPage/graphql/location/lng"/>
 140                         <xsl:value-of select="concat(' (', $location-latitude, ', ', $location-longitude, ')')"/>
 141                     </xsl:if>
 142                     <xsl:variable name="external-url" select="//user/external_url"/>
 143                     <xsl:if test="$external-url != ''">
 144                         <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 145                     </xsl:if>
 146                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 147                 </description>
 148                 <xsl:if test="$channel-image != ''">
 149                     <image>
 150                         <title>
 151                             <xsl:value-of select="$channel-title"/>
 152                         </title>
 153                         <link>
 154                             <xsl:value-of select="$channel-link"/>
 155                         </link>
 156                         <url>
 157                             <xsl:value-of select="$channel-image"/>
 158                         </url>
 159                     </image>
 160                 </xsl:if>
 161                 <xsl:apply-templates select="//ProfilePage/graphql/user/edge_owner_to_timeline_media/edges/node|//LocationsPage/graphql/location/edge_location_to_media/edges/node"/>
 162             </channel>
 163         </rss>
 164     </xsl:template>
 165 </xsl:stylesheet>