src/rss_converter_pump.io.xsl

   1 <!--
   2   Stylesheet to convert Pump.io activity streams to RSS.
   3
   4   Copyright (C) 2013-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <!-- To Evan, please reconsider publishing RSS ouput for _public_ contents -->
  22 <xsl:stylesheet version="1.0"
  23     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  24     xmlns:php="http://php.net/xsl"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:output method="xml" indent="yes"/>
  28
  29     <xsl:variable name="domain-name" select="substring-after(//div[@id='profile-block']/@data-profile-id, '@')"/>
  30     <xsl:variable name="BaseURL" select="concat('https://', $domain-name)"/>
  31
  32     <xsl:variable name="user-name" select="substring-after(//div[@id='profile-block']/@data-profile-id, ':')"/>
  33
  34     <xsl:template match="//div[@id='user-content-activities']//ul[@id='major-stream']/li">
  35         <xsl:variable name="item-content" select=".//div[@class='activity-content']"/>
  36         <xsl:variable name="item-permalink" select=".//p[@class='muted']/small/a/@href"/>
  37         <item>
  38             <title>
  39                 <xsl:value-of select="concat($user-name, ': ', normalize-space($item-content))"/>
  40             </title>
  41             <link>
  42                 <xsl:value-of select="$item-permalink"/>
  43             </link>
  44             <guid>
  45                 <xsl:value-of select="$item-permalink"/>
  46             </guid>
  47             <pubDate>
  48                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::strToRssDate', .//abbr[@class='easydate']/@title)"/>
  49             </pubDate>
  50             <description>
  51                 <xsl:value-of select="concat($user-name, ': ')"/>
  52                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  53                 <xsl:copy-of select="$item-content/node()"/>
  54                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  55             </description>
  56             <xsl:if test="$generate-enclosure = 1">
  57                 <xsl:variable name="image-thumb-link" select=".//img[contains(@class, 'object-image')]/@src"/>
  58                 <xsl:if test="$image-thumb-link">
  59                     <xsl:variable name="image-link" select="php:functionString('str_replace', '_thumb', '', $image-thumb-link)"/>
  60                     <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $image-link)"/>
  61                 </xsl:if>
  62             </xsl:if>
  63         </item>
  64     </xsl:template>
  65
  66     <xsl:template match="/">
  67         <xsl:variable name="channel-title" select="concat(substring-after($user-name, '@'), ' / ', substring-before($user-name, '@'))"/>
  68         <xsl:variable name="channel-link" select="concat('https://', substring-after($user-name, '@'), '/', substring-before($user-name, '@'))"/>
  69
  70         <rss version="2.0">
  71             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  72             <channel>
  73                 <generator>Tweeper</generator>
  74                 <title>
  75                     <xsl:value-of select="$channel-title"/>
  76                 </title>
  77                 <link>
  78                     <xsl:value-of select="$channel-link"/>
  79                 </link>
  80                 <description>
  81                     <xsl:value-of select="normalize-space(//h1[@class='media-header'])"/>
  82                 </description>
  83                 <image>
  84                     <title>
  85                         <xsl:value-of select="$channel-title"/>
  86                     </title>
  87                     <link>
  88                         <xsl:value-of select="$channel-link"/>
  89                     </link>
  90                     <url>
  91                         <xsl:value-of select="//div[@id='profile-block']/span/img[contains(@class, 'img-rounded media-object')]/@src"/>
  92                     </url>
  93                 </image>
  94                 <xsl:apply-templates select="//div[@id='user-content-activities']//ul[@id='major-stream']/li"/>
  95             </channel>
  96         </rss>
  97     </xsl:template>
  98 </xsl:stylesheet>