src/rss_converter_twitter.com.xsl

   1 <!--
   2   Stylesheet to convert Twitter user timelines to RSS.
   3
   4   Copyright (C) 2013-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     exclude-result-prefixes="php">
  25
  26     <xsl:param name="generate-enclosure"/>
  27
  28     <xsl:output method="xml" indent="yes"/>
  29
  30     <xsl:variable name="BaseURL">
  31         <xsl:text>https://twitter.com</xsl:text>
  32     </xsl:variable>
  33
  34     <!-- Identity transform -->
  35     <xsl:template match="@*|node()">
  36         <xsl:copy>
  37             <!--
  38                 Strip the style attribute while copying elements because it may be
  39                 dangerous, see:
  40                 https://validator.w3.org/feed/docs/warning/DangerousStyleAttr.html
  41             -->
  42             <xsl:apply-templates select="@*[not(name() = 'style')]|node()"/>
  43         </xsl:copy>
  44     </xsl:template>
  45
  46     <!--
  47          Anchors to external links provide the direct URL in the
  48          data-expanded-url attribute, so use this in the href attribute too
  49          instead of the default short URL which uses the t.co redirection
  50          service.
  51
  52          NOTE: when creating an element, attributes must be processed _before_
  53          adding the contents (either children or a value):
  54          http://stackoverflow.com/questions/21984867/
  55     -->
  56     <xsl:template match="a[@data-expanded-url]">
  57         <!-- Prepend and append a white space for aestethic reasons -->
  58         <xsl:text> </xsl:text>
  59         <a>
  60             <xsl:attribute name="href">
  61                 <xsl:value-of select="@data-expanded-url"/>
  62             </xsl:attribute>
  63             <!-- Also strip &nbsp; and &hellip; -->
  64             <xsl:value-of select="translate(., '&#xA0;&#x2026;', '')"/>
  65         </a>
  66         <xsl:text> </xsl:text>
  67     </xsl:template>
  68
  69     <!--
  70          These are links to pic.twitter.com, use the direct link for those
  71          too instead of the t.co redirections.
  72     -->
  73     <xsl:template match="a[@data-pre-embedded='true']">
  74         <!-- Prepend and append a white space for aestethic reasons -->
  75         <xsl:text> </xsl:text>
  76         <a>
  77             <xsl:attribute name="href">
  78                 <xsl:value-of select="concat('https://', .)"/>
  79             </xsl:attribute>
  80             <xsl:value-of select="concat('https://', .)"/>
  81         </a>
  82         <xsl:text> </xsl:text>
  83     </xsl:template>
  84
  85     <!-- Present images in a more convenient way -->
  86     <xsl:template match="div[@data-image-url]">
  87         <a>
  88             <xsl:attribute name="href">
  89                 <xsl:value-of select="concat(@data-image-url, ':orig')"/>
  90             </xsl:attribute>
  91             <img style="max-width: 100%">
  92                 <xsl:attribute name="src">
  93                     <xsl:value-of select="@data-image-url"/>
  94                 </xsl:attribute>
  95             </img>
  96         </a>
  97     </xsl:template>
  98
  99     <!-- Don't repeat background in embedded media content -->
 100     <xsl:template match="div[contains(@class, 'PlayableMedia-player')]">
 101         <xsl:copy>
 102             <xsl:apply-templates select="@*"/>
 103             <xsl:attribute name="style">
 104                 <xsl:value-of select="concat(@style, '; background-repeat: no-repeat; background-size: 100% auto')"/>
 105             </xsl:attribute>
 106             <xsl:apply-templates select="node()"/>
 107         </xsl:copy>
 108     </xsl:template>
 109
 110     <xsl:template match="a[@data-expanded-url]" mode="enclosure">
 111         <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', ./@data-expanded-url)"/>
 112     </xsl:template>
 113
 114     <xsl:template match="div[@data-image-url]" mode="enclosure">
 115         <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', concat(./@data-image-url, ':orig'))"/>
 116     </xsl:template>
 117
 118     <xsl:variable name="screen-name" select="//div[@class='user-actions btn-group not-following ']/@data-screen-name"/>
 119
 120     <xsl:template match="//div[@class='permalink-inner permalink-tweet-container'] | //li[@data-item-id and @data-item-type='tweet']">
 121         <xsl:variable name="user-name" select=".//div[@data-tweet-id]/@data-screen-name"/>
 122         <xsl:variable name="item-content" select=".//p[contains(@class, 'js-tweet-text')]"/>
 123         <xsl:variable name="item-media" select=".//div[contains(@class, 'AdaptiveMedia-container')]"/>
 124         <xsl:variable name="item-permalink" select="concat($BaseURL, .//div[@data-permalink-path]/@data-permalink-path)"/>
 125
 126         <xsl:variable name="item-has-video" select="$item-media//*[contains(@class, 'PlayableMedia--video')]"/>
 127         <xsl:variable name="item-has-gif" select="$item-media//*[contains(@class, 'PlayableMedia--gif')]"/>
 128         <item>
 129             <title>
 130                 <xsl:value-of select="concat($user-name, ': ')"/>
 131                 <xsl:if test="$item-has-video">
 132                     <xsl:text>(Video) </xsl:text>
 133                 </xsl:if>
 134                 <!--
 135                      Prepend a space in front of the URLs which are not
 136                      preceded by an open parenthesis, for aestethic reasons.
 137                      Also, regex, I know: http://xkcd.com/1171/
 138                 -->
 139                 <xsl:variable
 140                     name="processed-title"
 141                     select="php:functionString('preg_replace', '@((?&lt;!\()(?:http[s]?://|pic.twitter.com))@', ' \1', $item-content)"/>
 142                 <!-- Also strip &nbsp; and &hellip; -->
 143                 <xsl:value-of select="normalize-space(translate($processed-title, '&#xA0;&#x2026;', ''))"/>
 144             </title>
 145             <link>
 146                 <xsl:value-of select="$item-permalink"/>
 147             </link>
 148             <guid>
 149                 <xsl:value-of select="$item-permalink"/>
 150             </guid>
 151             <pubDate>
 152                 <xsl:variable name="timestamp" select=".//span[contains(@class, 'js-short-timestamp')]/@data-time"/>
 153                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', number($timestamp))"/>
 154             </pubDate>
 155             <description>
 156                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 157                 <xsl:value-of select="concat($user-name, ':')"/>
 158                 <xsl:element name="br"/>
 159                 <xsl:if test="$item-has-video">
 160                     <xsl:text> (Video)</xsl:text>
 161                     <xsl:element name="br"/>
 162                 </xsl:if>
 163                 <xsl:if test="$item-has-gif">
 164                     <xsl:text> (GIF)</xsl:text>
 165                     <xsl:element name="br"/>
 166                 </xsl:if>
 167                 <xsl:element name="span">
 168                     <xsl:attribute name="style">white-space: pre-wrap;</xsl:attribute>
 169                     <xsl:apply-templates select="$item-content/node()"/>
 170                 </xsl:element>
 171                 <xsl:apply-templates select="$item-media/node()"/>
 172                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 173             </description>
 174             <xsl:if test="$generate-enclosure = 1">
 175                 <xsl:apply-templates select="$item-content//a[@data-expanded-url]" mode="enclosure"/>
 176                 <xsl:apply-templates select="$item-media//div[@data-image-url]" mode="enclosure"/>
 177             </xsl:if>
 178         </item>
 179     </xsl:template>
 180
 181     <xsl:template match="/">
 182         <xsl:variable name="channel-title">
 183             <xsl:choose>
 184                 <xsl:when test="$screen-name != ''">
 185                     <xsl:value-of select="concat('Twitter / ', $screen-name)"/>
 186                 </xsl:when>
 187                 <xsl:otherwise>
 188                     <xsl:value-of select="concat('Twitter / ', normalize-space(//h1[1]))"/>
 189                 </xsl:otherwise>
 190             </xsl:choose>
 191         </xsl:variable>
 192         <xsl:variable name="channel-link" select="//link[@rel='canonical']/@href"/>
 193         <xsl:variable name="channel-image" select="//a[contains(@class, 'profile-picture')]/@href"/>
 194
 195         <rss version="2.0">
 196             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 197             <channel>
 198                 <generator>Tweeper</generator>
 199                 <title>
 200                     <xsl:value-of select="$channel-title"/>
 201                 </title>
 202                 <link>
 203                     <xsl:value-of select="$channel-link"/>
 204                 </link>
 205                 <description>
 206                     <xsl:value-of select="normalize-space(//div[@class='ProfileHeaderCard'])"/>
 207                     <!-- The following rule should only match on hashtag URLs -->
 208                     <xsl:value-of select="normalize-space(//div[@class='SearchNavigation-textContainer'])"/>
 209                 </description>
 210                 <xsl:if test="$channel-image != ''">
 211                     <image>
 212                         <title>
 213                             <xsl:value-of select="$channel-title"/>
 214                         </title>
 215                         <link>
 216                             <xsl:value-of select="$channel-link"/>
 217                         </link>
 218                         <url>
 219                             <xsl:value-of select="$channel-image"/>
 220                         </url>
 221                     </image>
 222                 </xsl:if>
 223                 <xsl:apply-templates select="//ol[@id='stream-items-id']/li[@data-item-id and @data-item-type='tweet' and not(contains(@class, 'has-profile-promoted-tweet'))]"/>
 224
 225                 <!-- These rules will only match on permalink URLs -->
 226                 <xsl:apply-templates select="//div[@class='permalink-inner permalink-tweet-container']"/>
 227                 <xsl:apply-templates select="//div[@data-component-context='replies']//li[@data-item-id and @data-item-type='tweet' and not(contains(@class, 'has-profile-promoted-tweet'))]"/>
 228
 229             </channel>
 230         </rss>
 231     </xsl:template>
 232 </xsl:stylesheet>