src/rss_converter_dilbert.com.xsl

   1 <!--
   2   Stylesheet to convert Dilbert daily strips to RSS.
   3
   4   Copyright (C) 2013-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <!--
  23   Since June 18, 2013 dilbert.com strips are not accessible anymore
  24   directly from the RSS feed, this message is displayed instead:
  25
  26     Dilbert readers - Please visit Dilbert.com to read this feature. Due
  27     to changes with our feeds, we are now making this RSS feed a link to
  28     Dilbert.com.
  29
  30   How unhandy is that, was it because of a management decision?
  31   Maybe a parody dilbert strip is needed about this issue...
  32 -->
  33
  34 <xsl:stylesheet version="1.0"
  35     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  36     xmlns:php="http://php.net/xsl"
  37     exclude-result-prefixes="php">
  38
  39     <xsl:output method="xml" indent="yes"/>
  40
  41     <xsl:variable name="BaseURL" select="//meta[@property='og:url']/@content"/>
  42
  43     <xsl:template match="//section[@class='comic-item']">
  44         <xsl:variable name="item-permalink" select=".//a[@class='img-comic-link']/@href"/>
  45         <xsl:variable name="picture-url" select=".//img[@class='img-responsive img-comic']/@src"/>
  46         <xsl:variable name="picture-title" select=".//img[@class='img-responsive img-comic']/@alt"/>
  47         <item>
  48             <title>
  49                 <xsl:variable name="title-length" select="140"/>
  50                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  51                 <xsl:choose>
  52                     <xsl:when test="string-length($picture-title) > $title-length">
  53                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  54                         <xsl:value-of select="substring($picture-title, 1, $truncated-length)"/>
  55                         <xsl:text>...</xsl:text>
  56                     </xsl:when>
  57                     <xsl:otherwise>
  58                         <xsl:value-of select="$picture-title"/>
  59                     </xsl:otherwise>
  60                 </xsl:choose>
  61             </title>
  62             <link>
  63                 <xsl:value-of select="$item-permalink"/>
  64             </link>
  65             <guid>
  66                 <xsl:value-of select="$item-permalink"/>
  67             </guid>
  68             <pubDate>
  69                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::strToRssDate', normalize-space(.//date))"/>
  70             </pubDate>
  71             <description>
  72                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  73                 <img src="{$picture-url}" alt="{$picture-title}"/>
  74                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  75             </description>
  76             <xsl:if test="$generate-enclosure = 1">
  77                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $picture-url)"/>
  78             </xsl:if>
  79         </item>
  80     </xsl:template>
  81
  82     <xsl:template match="/">
  83         <xsl:variable name="channel-title" select="//meta[@property='og:title']/@content"/>
  84         <xsl:variable name="channel-link" select="$BaseURL"/>
  85
  86         <rss version="2.0">
  87             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  88             <channel>
  89                 <generator>Tweeper</generator>
  90                 <title>
  91                     <xsl:value-of select="$channel-title"/>
  92                 </title>
  93                 <link>
  94                     <xsl:value-of select="$channel-link"/>
  95                 </link>
  96                 <description>
  97                     <xsl:value-of select="//meta[@property='og:description']/@content"/>
  98                 </description>
  99                 <image>
 100                     <title>
 101                         <xsl:value-of select="$channel-title"/>
 102                     </title>
 103                     <link>
 104                         <xsl:value-of select="$channel-link"/>
 105                     </link>
 106                     <url>
 107                         <xsl:value-of select="concat($BaseURL, //img[@alt='Dilbert logo']/@src)"/>
 108                     </url>
 109                 </image>
 110                 <xsl:apply-templates select="//section[@class='comic-item']"/>
 111             </channel>
 112         </rss>
 113     </xsl:template>
 114 </xsl:stylesheet>