Fix a typo: s/tweeter/Twitter/
[tweeper.git] / rss_converter_dilbert.com.xsl
1 <!--
2   Stylesheet to convert Dilbert daily strips to RSS.
3
4   Copyright (C) 2013  Antonio Ospite <ospite@studenti.unina.it>
5
6   This file is part of tweeper.
7
8   This program is free software: you can redistribute it and/or modify
9   it under the terms of the GNU General Public License as published by
10   the Free Software Foundation, either version 3 of the License, or
11   (at your option) any later version.
12
13   This program is distributed in the hope that it will be useful,
14   but WITHOUT ANY WARRANTY; without even the implied warranty of
15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16   GNU General Public License for more details.
17
18   You should have received a copy of the GNU General Public License
19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
20 -->
21
22 <!--
23   Since June 18, 2013 dilbert.com strips are not accessible anymore
24   directly from the RSS feed, this message is displayed instead:
25
26     Dilbert readers - Please visit Dilbert.com to read this feature. Due
27     to changes with our feeds, we are now making this RSS feed a link to
28     Dilbert.com.
29
30   How unhandy is that, was it because of a management decision?
31   Maybe a parody dilbert strip is needed about this issue...
32 -->
33
34 <xsl:stylesheet version="1.0"
35     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
36     xmlns:php="http://php.net/xsl"
37     xsl:extension-element-prefixes="php">
38
39     <xsl:output method="xml" indent="yes"/>
40
41     <xsl:variable name="BaseURL" select="concat('http://', //meta[@property='og:site_name']/@content)"/>
42
43     <xsl:template match="//a[@id='strip_zoom']">
44         <xsl:variable name="picture-id" select="substring-after(./@href, '#')"/>
45         <xsl:variable name="picture-element" select="//div[@id=$picture-id]/img"/>
46         <xsl:variable name="picture-print-url" select="php:functionString('str_replace', 'zoom', 'print', $picture-element/@src)"/>
47         <item>
48             <title>
49                 <xsl:value-of select="$picture-element/@title"/>
50             </title>
51             <link>
52                 <xsl:value-of select="concat($BaseURL, $picture-element/@src)"/>
53             </link>
54             <pubDate>
55                 <xsl:value-of select="php:functionString('str_to_gmdate', substring-after($picture-id, 'strip_enlarged_'))"/>
56             </pubDate>
57             <description>
58                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
59                 <img src="{$picture-print-url}" />
60                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
61             </description>
62         </item>
63     </xsl:template>
64
65     <xsl:template match="/">
66
67         <rss version="2.0">
68             <channel>
69                 <generator>Tweeper</generator>
70                 <title>
71                     <xsl:value-of select="//meta[@property='og:title']/@content"/>
72                 </title>
73                 <link>
74                     <xsl:value-of select="$BaseURL"/>
75                 </link>
76                 <description>
77                     <xsl:value-of select="//meta[@property='og:description']/@content"/>
78                 </description>
79                 <image>
80                     <url>
81                         <xsl:value-of select="//meta[@property='og:image']/@content"/>
82                     </url>
83                 </image>
84                 <xsl:apply-templates select="//a[@id='strip_zoom']"/>
85             </channel>
86         </rss>
87     </xsl:template>
88 </xsl:stylesheet>