src/rss_converter_pump.io.xsl

   1 <!--
   2   Stylesheet to convert Pump.io activity streams to RSS.
   3
   4   Copyright (C) 2013-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <!-- To Evan, please reconsider publishing RSS ouput for _public_ contents -->
  22 <xsl:stylesheet version="1.0"
  23     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  24     xmlns:php="http://php.net/xsl"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="domain-name" select="substring-after(//div[@id='profile-block']/@data-profile-id, '@')"/>
  32     <xsl:variable name="BaseURL" select="concat('https://', $domain-name)"/>
  33
  34     <xsl:variable name="user-name" select="substring-after(//div[@id='profile-block']/@data-profile-id, ':')"/>
  35
  36     <xsl:template match="//div[@id='user-content-activities']//ul[@id='major-stream']/li">
  37         <xsl:variable name="item-content" select=".//div[@class='activity-content']"/>
  38         <xsl:variable name="item-permalink" select=".//p[@class='muted']/small/a/@href"/>
  39         <item>
  40             <title>
  41                 <xsl:value-of select="concat($user-name, ': ', normalize-space($item-content))"/>
  42             </title>
  43             <link>
  44                 <xsl:value-of select="$item-permalink"/>
  45             </link>
  46             <guid>
  47                 <xsl:value-of select="$item-permalink"/>
  48             </guid>
  49             <pubDate>
  50                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::strToRssDate', .//abbr[@class='easydate']/@title)"/>
  51             </pubDate>
  52             <description>
  53                 <xsl:value-of select="concat($user-name, ': ')"/>
  54                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  55                 <xsl:copy-of select="$item-content/node()"/>
  56                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  57             </description>
  58             <xsl:if test="$generate-enclosure = 1">
  59                 <xsl:variable name="image-thumb-link" select=".//img[contains(@class, 'object-image')]/@src"/>
  60                 <xsl:if test="$image-thumb-link">
  61                     <xsl:variable name="image-link" select="php:functionString('str_replace', '_thumb', '', $image-thumb-link)"/>
  62                     <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $image-link)"/>
  63                 </xsl:if>
  64             </xsl:if>
  65         </item>
  66     </xsl:template>
  67
  68     <xsl:template match="/">
  69         <xsl:variable name="channel-title" select="concat(substring-after($user-name, '@'), ' / ', substring-before($user-name, '@'))"/>
  70         <xsl:variable name="channel-link" select="concat('https://', substring-after($user-name, '@'), '/', substring-before($user-name, '@'))"/>
  71
  72         <rss version="2.0">
  73             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  74             <channel>
  75                 <generator>Tweeper</generator>
  76                 <title>
  77                     <xsl:value-of select="$channel-title"/>
  78                 </title>
  79                 <link>
  80                     <xsl:value-of select="$channel-link"/>
  81                 </link>
  82                 <description>
  83                     <xsl:value-of select="normalize-space(//h1[@class='media-header'])"/>
  84                 </description>
  85                 <image>
  86                     <title>
  87                         <xsl:value-of select="$channel-title"/>
  88                     </title>
  89                     <link>
  90                         <xsl:value-of select="$channel-link"/>
  91                     </link>
  92                     <url>
  93                         <xsl:value-of select="//div[@id='profile-block']/span/img[contains(@class, 'img-rounded media-object')]/@src"/>
  94                     </url>
  95                 </image>
  96                 <xsl:apply-templates select="//div[@id='user-content-activities']//ul[@id='major-stream']/li"/>
  97             </channel>
  98         </rss>
  99     </xsl:template>
 100 </xsl:stylesheet>