src/rss_converter_dilbert.com.xsl

   1 <!--
   2   Stylesheet to convert Dilbert daily strips to RSS.
   3
   4   Copyright (C) 2013-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <!--
  23   Since June 18, 2013 dilbert.com strips are not accessible anymore
  24   directly from the RSS feed, this message is displayed instead:
  25
  26     Dilbert readers - Please visit Dilbert.com to read this feature. Due
  27     to changes with our feeds, we are now making this RSS feed a link to
  28     Dilbert.com.
  29
  30   How unhandy is that, was it because of a management decision?
  31   Maybe a parody dilbert strip is needed about this issue...
  32 -->
  33
  34 <xsl:stylesheet version="1.0"
  35     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  36     xmlns:php="http://php.net/xsl"
  37     exclude-result-prefixes="php">
  38
  39     <xsl:param name="generate-enclosure"/>
  40
  41     <xsl:output method="xml" indent="yes"/>
  42
  43     <xsl:variable name="BaseURL" select="//meta[@property='og:url']/@content"/>
  44
  45     <xsl:template match="//section[@class='comic-item']">
  46         <xsl:variable name="item-permalink" select=".//a[@class='img-comic-link']/@href"/>
  47         <xsl:variable name="picture-url" select=".//img[@class='img-responsive img-comic']/@src"/>
  48         <xsl:variable name="picture-title" select=".//img[@class='img-responsive img-comic']/@alt"/>
  49         <item>
  50             <title>
  51                 <xsl:variable name="title-length" select="140"/>
  52                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  53                 <xsl:choose>
  54                     <xsl:when test="string-length($picture-title) > $title-length">
  55                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  56                         <xsl:value-of select="substring($picture-title, 1, $truncated-length)"/>
  57                         <xsl:text>...</xsl:text>
  58                     </xsl:when>
  59                     <xsl:otherwise>
  60                         <xsl:value-of select="$picture-title"/>
  61                     </xsl:otherwise>
  62                 </xsl:choose>
  63             </title>
  64             <link>
  65                 <xsl:value-of select="$item-permalink"/>
  66             </link>
  67             <guid>
  68                 <xsl:value-of select="$item-permalink"/>
  69             </guid>
  70             <pubDate>
  71                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::strToRssDate', normalize-space(.//date))"/>
  72             </pubDate>
  73             <description>
  74                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  75                 <img src="{$picture-url}" alt="{$picture-title}"/>
  76                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  77             </description>
  78             <xsl:if test="$generate-enclosure = 1">
  79                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $picture-url)"/>
  80             </xsl:if>
  81         </item>
  82     </xsl:template>
  83
  84     <xsl:template match="/">
  85         <xsl:variable name="channel-title" select="//meta[@property='og:title']/@content"/>
  86         <xsl:variable name="channel-link" select="$BaseURL"/>
  87
  88         <rss version="2.0">
  89             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  90             <channel>
  91                 <generator>Tweeper</generator>
  92                 <title>
  93                     <xsl:value-of select="$channel-title"/>
  94                 </title>
  95                 <link>
  96                     <xsl:value-of select="$channel-link"/>
  97                 </link>
  98                 <description>
  99                     <xsl:value-of select="//meta[@property='og:description']/@content"/>
 100                 </description>
 101                 <image>
 102                     <title>
 103                         <xsl:value-of select="$channel-title"/>
 104                     </title>
 105                     <link>
 106                         <xsl:value-of select="$channel-link"/>
 107                     </link>
 108                     <url>
 109                         <xsl:value-of select="concat($BaseURL, //img[@alt='Dilbert logo']/@src)"/>
 110                     </url>
 111                 </image>
 112                 <xsl:apply-templates select="//section[@class='comic-item']"/>
 113             </channel>
 114         </rss>
 115     </xsl:template>
 116 </xsl:stylesheet>