src/rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:variable name="user-name" select="//ProfilePage/graphql/user/username"/>
  36
  37     <!--
  38          NOTE: some users do not specify the full name.
  39
  40          Remember to handle this case when using it and fall-back to the plain
  41          user name when appropriate.
  42     -->
  43     <xsl:variable name="full-name" select="//ProfilePage/graphql/user/full_name"/>
  44
  45     <xsl:variable name="location-name" select="//LocationsPage/graphql/location/name"/>
  46
  47     <xsl:variable name="screen-name">
  48         <xsl:choose>
  49             <xsl:when test="$location-name != ''">
  50                 <xsl:variable name="location-latitude" select="//LocationsPage/location/lat"/>
  51                 <xsl:variable name="location-longitude" select="//LocationsPage/location/lng"/>
  52                 <xsl:value-of select="concat($location-name, ' (', $location-latitude, ', ', $location-longitude, ')')"/>
  53             </xsl:when>
  54             <xsl:when test="$full-name != ''">
  55                 <xsl:value-of select="$full-name"/>
  56             </xsl:when>
  57             <xsl:otherwise>
  58                 <xsl:value-of select="$user-name"/>
  59             </xsl:otherwise>
  60         </xsl:choose>
  61     </xsl:variable>
  62
  63     <xsl:template match="//edges/node">
  64         <xsl:variable name="item-content-image" select="./display_url"/>
  65         <xsl:variable name="item-content-caption" select="./edge_media_to_caption/edges/node/text"/>
  66         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./shortcode, '/')"/>
  67         <item>
  68             <title>
  69                 <xsl:variable name="title-length" select="140"/>
  70                 <xsl:variable name="item-content-title" select="normalize-space(concat($screen-name, ': ', $item-content-caption))"/>
  71                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  72                 <xsl:choose>
  73                     <xsl:when test="string-length($item-content-title) > $title-length">
  74                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  75                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  76                         <xsl:text>...</xsl:text>
  77                     </xsl:when>
  78                     <xsl:otherwise>
  79                         <xsl:value-of select="$item-content-title"/>
  80                     </xsl:otherwise>
  81                 </xsl:choose>
  82             </title>
  83             <link>
  84                 <xsl:value-of select="$item-permalink"/>
  85             </link>
  86             <guid>
  87                 <xsl:value-of select="$item-permalink"/>
  88             </guid>
  89             <pubDate>
  90                 <xsl:variable name="timestamp" select="./taken_at_timestamp"/>
  91                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
  92             </pubDate>
  93             <description>
  94                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  95                 <p>
  96                     <xsl:if test="./is_video/text() = 1">
  97                         (Video)
  98                     </xsl:if>
  99                     <xsl:value-of select="$item-content-caption"/>
 100                 </p><br />
 101                 <a href="{$item-permalink}"><img src="{$item-content-image}" style="max-width: 100%"/></a>
 102                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 103             </description>
 104             <xsl:if test="$generate-enclosure = 1">
 105                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $item-content-image)"/>
 106             </xsl:if>
 107         </item>
 108     </xsl:template>
 109
 110     <xsl:template match="/">
 111
 112         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 113         <xsl:variable name="channel-link">
 114             <xsl:choose>
 115                 <xsl:when test="$location-name != ''">
 116                     <xsl:variable name="location-id" select="//LocationsPage/graphql/location/id"/>
 117                     <xsl:value-of select="concat($BaseURL, '/explore/locations/', $location-id)"/>
 118                 </xsl:when>
 119                 <xsl:otherwise>
 120                     <xsl:value-of select="concat($BaseURL, '/', $user-name)"/>
 121                 </xsl:otherwise>
 122             </xsl:choose>
 123         </xsl:variable>
 124         <xsl:variable name="channel-image" select="//ProfilePage/graphql/user/profile_pic_url"/>
 125
 126         <rss version="2.0">
 127             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 128             <channel>
 129                 <generator>Tweeper</generator>
 130                 <title>
 131                     <xsl:value-of select="$channel-title"/>
 132                 </title>
 133                 <link>
 134                     <xsl:value-of select="$channel-link"/>
 135                 </link>
 136                 <description>
 137                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 138                     <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 139                     <xsl:variable name="external-url" select="//user/external_url"/>
 140                     <xsl:if test="$external-url != ''">
 141                         <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 142                     </xsl:if>
 143                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 144                 </description>
 145                 <xsl:if test="$channel-image != ''">
 146                     <image>
 147                         <title>
 148                             <xsl:value-of select="$channel-title"/>
 149                         </title>
 150                         <link>
 151                             <xsl:value-of select="$channel-link"/>
 152                         </link>
 153                         <url>
 154                             <xsl:value-of select="$channel-image"/>
 155                         </url>
 156                     </image>
 157                 </xsl:if>
 158                 <xsl:apply-templates select="//ProfilePage/graphql/user/edge_owner_to_timeline_media/edges/node|//LocationsPage/graphql/location/edge_location_to_media/edges/node"/>
 159             </channel>
 160         </rss>
 161     </xsl:template>
 162 </xsl:stylesheet>