rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generateEnclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:template match="images">
  36         <xsl:value-of disable-output-escaping="yes" select="php:function('Tweeper::generate_enclosure', string(./standard_resolution/url))"/>
  37     </xsl:template>
  38
  39     <xsl:variable name="screen-name" select="//ProfilePage/XML_Serializer_Tag/user/full_name"/>
  40     <xsl:variable name="user-name" select="//ProfilePage/XML_Serializer_Tag/user/username"/>
  41
  42     <xsl:template match="//media/nodes/XML_Serializer_Tag">
  43         <xsl:variable name="item-content-image" select="./display_src"/>
  44         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./code, '/')"/>
  45         <xsl:variable name="item-content-title" select="concat($user-name, ': ', $item-permalink, ', comments: ', ./comments/count, ', likes: ', ./likes/count)"/>
  46         <item>
  47             <title>
  48                 <xsl:value-of select="$item-content-title"/>
  49             </title>
  50             <link>
  51                 <xsl:value-of select="$item-permalink"/>
  52             </link>
  53             <guid>
  54                 <xsl:value-of select="$item-permalink"/>
  55             </guid>
  56             <pubDate>
  57                 <xsl:variable name="timestamp" select="./date"/>
  58                 <xsl:value-of select="php:functionString('Tweeper::epoch_to_gmdate', number($timestamp))"/>
  59             </pubDate>
  60             <description>
  61                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  62                 <p><xsl:value-of select="$item-content-title"/></p><br />
  63                 <a href="{$item-permalink}"><img src="{$item-content-image}" /></a>
  64                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  65             </description>
  66             <xsl:if test="$generateEnclosure = 1">
  67                 <xsl:apply-templates select="./images"/>
  68             </xsl:if>
  69         </item>
  70     </xsl:template>
  71
  72     <xsl:template match="/">
  73         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
  74         <xsl:variable name="channel-link" select="concat($BaseURL, //__path)"/>
  75
  76         <rss version="2.0">
  77             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  78             <channel>
  79                 <generator>Tweeper</generator>
  80                 <title>
  81                     <xsl:value-of select="$channel-title"/>
  82                 </title>
  83                 <link>
  84                     <xsl:value-of select="$channel-link"/>
  85                 </link>
  86                 <description>
  87                     <xsl:value-of select="//user/biography"/>
  88                 </description>
  89                 <image>
  90                     <title>
  91                         <xsl:value-of select="$channel-title"/>
  92                     </title>
  93                     <link>
  94                         <xsl:value-of select="$channel-link"/>
  95                     </link>
  96                     <url>
  97                         <xsl:value-of select="//user/profile_pic_url"/>
  98                     </url>
  99                 </image>
 100                 <xsl:apply-templates select="//media/nodes/XML_Serializer_Tag"/>
 101             </channel>
 102         </rss>
 103     </xsl:template>
 104 </xsl:stylesheet>