rss_converter_twitter.com.xsl

   1 <!--
   2   Stylesheet to convert Twitter user timelines to RSS.
   3
   4   Copyright (C) 2013  Antonio Ospite <ospite@studenti.unina.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php">
  25
  26     <xsl:output method="xml" indent="yes"/>
  27
  28     <xsl:variable name="twitterBaseURL">
  29         <xsl:text>https://twitter.com</xsl:text>
  30     </xsl:variable>
  31
  32     <xsl:variable name="screen-name" select="//div[@class='profile-card-inner']/@data-screen-name"/>
  33
  34     <xsl:template match="//div[@id='timeline']//ol[@id='stream-items-id']//li[@data-item-type='tweet']">
  35         <xsl:variable name="tweet-text" select=".//p[@class='js-tweet-text tweet-text']"/>
  36         <item>
  37             <title>
  38                 <xsl:value-of select="concat($screen-name, ': ', $tweet-text)"/>
  39             </title>
  40             <link>
  41                 <xsl:value-of select="concat($twitterBaseURL, .//a[@class='details with-icn js-details']/@href)"/>
  42             </link>
  43             <pubDate>
  44                 <xsl:value-of select="php:functionString('epoch_to_gmdate', .//small[@class='time']//span/@data-time)"/>
  45             </pubDate>
  46             <description>
  47                 <xsl:value-of select="concat($screen-name, ': ')"/>
  48                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  49                 <xsl:copy-of select="$tweet-text/node()"/>
  50                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  51             </description>
  52             <xsl:value-of disable-output-escaping="yes" select="php:function('generate_enclosure', string(.//a[@class='twitter-timeline-link']/@data-expanded-url))"/>
  53         </item>
  54     </xsl:template>
  55
  56     <xsl:template match="/">
  57
  58         <rss version="2.0">
  59             <channel>
  60                 <generator>Tweeper</generator>
  61                 <title>
  62                     <xsl:text>Twitter / </xsl:text><xsl:value-of select="$screen-name"/>
  63                 </title>
  64                 <link>
  65                     <xsl:value-of select="//link[@rel='canonical']/@href"/>
  66                 </link>
  67                 <description>
  68                     <xsl:value-of select="//meta[@name='description']/@content"/>
  69                 </description>
  70                 <image>
  71                     <url>
  72                         <xsl:value-of select="//a[@class='profile-picture media-thumbnail']/@href"/>
  73                     </url>
  74                 </image>
  75                 <xsl:apply-templates select="//div[@id='timeline']//ol[@id='stream-items-id']//li[@data-item-type='tweet']"/>
  76             </channel>
  77         </rss>
  78     </xsl:template>
  79 </xsl:stylesheet>