src/rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:variable name="user-name" select="//ProfilePage/user/username"/>
  36
  37     <!--
  38          NOTE: some users do not specify the full name.
  39
  40          Remember to handle this case when using it and fall-back to the plain
  41          user name when appropriate.
  42     -->
  43     <xsl:variable name="full-name" select="//ProfilePage/user/full_name"/>
  44
  45     <xsl:variable name="screen-name">
  46         <xsl:choose>
  47             <xsl:when test="$full-name != ''">
  48                 <xsl:value-of select="$full-name"/>
  49             </xsl:when>
  50             <xsl:otherwise>
  51                 <xsl:value-of select="$user-name"/>
  52             </xsl:otherwise>
  53         </xsl:choose>
  54     </xsl:variable>
  55
  56     <xsl:template match="//ProfilePage/user/media/nodes">
  57         <xsl:variable name="item-content-image" select="./display_src"/>
  58         <xsl:variable name="item-content-caption" select="./caption"/>
  59         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./code, '/')"/>
  60         <item>
  61             <title>
  62                 <xsl:variable name="title-length" select="140"/>
  63                 <xsl:variable name="item-content-title" select="normalize-space(concat($user-name, ': ', $item-content-caption))"/>
  64                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  65                 <xsl:choose>
  66                     <xsl:when test="string-length($item-content-title) > $title-length">
  67                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  68                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  69                         <xsl:text>...</xsl:text>
  70                     </xsl:when>
  71                     <xsl:otherwise>
  72                         <xsl:value-of select="$item-content-title"/>
  73                     </xsl:otherwise>
  74                 </xsl:choose>
  75             </title>
  76             <link>
  77                 <xsl:value-of select="$item-permalink"/>
  78             </link>
  79             <guid>
  80                 <xsl:value-of select="$item-permalink"/>
  81             </guid>
  82             <pubDate>
  83                 <xsl:variable name="timestamp" select="./date"/>
  84                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
  85             </pubDate>
  86             <description>
  87                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  88                 <p>
  89                     <xsl:if test="./is_video/text() = 1">
  90                         (Video)
  91                     </xsl:if>
  92                     <xsl:value-of select="$item-content-caption"/>
  93                 </p><br />
  94                 <a href="{$item-permalink}"><img src="{$item-content-image}" style="max-width: 100%"/></a>
  95                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  96             </description>
  97             <xsl:if test="$generate-enclosure = 1">
  98                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $item-content-image)"/>
  99             </xsl:if>
 100         </item>
 101     </xsl:template>
 102
 103     <xsl:template match="/">
 104         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 105         <xsl:variable name="channel-link" select="concat($BaseURL, '/', $user-name)"/>
 106
 107         <rss version="2.0">
 108             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 109             <channel>
 110                 <generator>Tweeper</generator>
 111                 <title>
 112                     <xsl:value-of select="$channel-title"/>
 113                 </title>
 114                 <link>
 115                     <xsl:value-of select="$channel-link"/>
 116                 </link>
 117                 <description>
 118                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 119                     <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 120                     <xsl:variable name="external-url" select="//user/external_url"/>
 121                     <xsl:if test="$external-url != ''">
 122                         <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 123                     </xsl:if>
 124                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 125                 </description>
 126                 <image>
 127                     <title>
 128                         <xsl:value-of select="$channel-title"/>
 129                     </title>
 130                     <link>
 131                         <xsl:value-of select="$channel-link"/>
 132                     </link>
 133                     <url>
 134                         <xsl:value-of select="//ProfilePage/user/profile_pic_url"/>
 135                     </url>
 136                 </image>
 137                 <xsl:apply-templates select="//ProfilePage/user/media/nodes"/>
 138             </channel>
 139         </rss>
 140     </xsl:template>
 141 </xsl:stylesheet>