rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:template match="display_src">
  36         <xsl:value-of disable-output-escaping="yes" select="php:function('Tweeper::generateEnclosure', string(text()))"/>
  37     </xsl:template>
  38
  39     <xsl:variable name="user-name" select="//ProfilePage/user/username"/>
  40
  41     <!-- Some users do not specify the full name -->
  42     <xsl:variable name="full-name" select="//ProfilePage/user/full_name"/>
  43     <xsl:variable name="screen-name">
  44         <xsl:choose>
  45             <xsl:when test="$full-name != ''">
  46                 <xsl:value-of select="$full-name"/>
  47             </xsl:when>
  48             <xsl:otherwise>
  49                 <xsl:value-of select="$user-name"/>
  50             </xsl:otherwise>
  51         </xsl:choose>
  52     </xsl:variable>
  53
  54     <xsl:template match="//media/nodes">
  55         <xsl:variable name="item-content-image" select="./display_src"/>
  56         <xsl:variable name="item-content-caption" select="./caption"/>
  57         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./code, '/')"/>
  58         <item>
  59             <title>
  60                 <xsl:variable name="title-length" select="140"/>
  61                 <xsl:variable name="item-content-title" select="normalize-space(concat($user-name, ': ', $item-content-caption))"/>
  62                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  63                 <xsl:choose>
  64                     <xsl:when test="string-length($item-content-title) > $title-length">
  65                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  66                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  67                         <xsl:text>...</xsl:text>
  68                     </xsl:when>
  69                     <xsl:otherwise>
  70                         <xsl:value-of select="$item-content-title"/>
  71                     </xsl:otherwise>
  72                 </xsl:choose>
  73             </title>
  74             <link>
  75                 <xsl:value-of select="$item-permalink"/>
  76             </link>
  77             <guid>
  78                 <xsl:value-of select="$item-permalink"/>
  79             </guid>
  80             <pubDate>
  81                 <xsl:variable name="timestamp" select="./date"/>
  82                 <xsl:value-of select="php:functionString('Tweeper::epochToRssDate', number($timestamp))"/>
  83             </pubDate>
  84             <description>
  85                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  86                 <p>
  87                     <xsl:if test="./is_video/text() = 1">
  88                         (Video)
  89                     </xsl:if>
  90                     <xsl:value-of select="$item-content-caption"/>
  91                 </p><br />
  92                 <a href="{$item-permalink}"><img src="{$item-content-image}" /></a>
  93                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  94             </description>
  95             <xsl:if test="$generate-enclosure = 1">
  96                 <xsl:apply-templates select="./display_src"/>
  97             </xsl:if>
  98         </item>
  99     </xsl:template>
 100
 101     <xsl:template match="/">
 102         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 103         <xsl:variable name="channel-link" select="concat($BaseURL, //__path)"/>
 104
 105         <rss version="2.0">
 106             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 107             <channel>
 108                 <generator>Tweeper</generator>
 109                 <title>
 110                     <xsl:value-of select="$channel-title"/>
 111                 </title>
 112                 <link>
 113                     <xsl:value-of select="$channel-link"/>
 114                 </link>
 115                 <description>
 116                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 117                     <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 118                     <xsl:variable name="external-url" select="//user/external_url"/>
 119                     <xsl:if test="$external-url != ''">
 120                         <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 121                     </xsl:if>
 122                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 123                 </description>
 124                 <image>
 125                     <title>
 126                         <xsl:value-of select="$channel-title"/>
 127                     </title>
 128                     <link>
 129                         <xsl:value-of select="$channel-link"/>
 130                     </link>
 131                     <url>
 132                         <xsl:value-of select="//user/profile_pic_url"/>
 133                     </url>
 134                 </image>
 135                 <xsl:apply-templates select="//media/nodes"/>
 136             </channel>
 137         </rss>
 138     </xsl:template>
 139 </xsl:stylesheet>