rss_converter_twitter.com.xsl

   1 <!--
   2   Stylesheet to convert Twitter user timelines to RSS.
   3
   4   Copyright (C) 2013-2014  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://twitter.com</xsl:text>
  33     </xsl:variable>
  34
  35     <!-- Identity transform -->
  36     <xsl:template match="@*|node()">
  37         <xsl:copy>
  38             <xsl:apply-templates select="@*|node()"/>
  39         </xsl:copy>
  40     </xsl:template>
  41
  42     <!--
  43          Anchors to external links provide the direct URL in the
  44          data-expanded-url attribute, so use this in the href attribute too
  45          instead of the default short URL which uses the t.co redirection
  46          service.
  47
  48          NOTE: when creating an element, attributes must be processed _before_
  49          adding the contents (either children or a value):
  50          http://stackoverflow.com/questions/21984867/
  51     -->
  52     <xsl:template match="a[@data-expanded-url]">
  53         <!-- Prepend and append a white space for aestethic reasons -->
  54         <xsl:text> </xsl:text>
  55         <a>
  56             <xsl:attribute name="href">
  57                 <xsl:value-of select="@data-expanded-url"/>
  58             </xsl:attribute>
  59             <!-- Also strip &nbsp; and &hellip; -->
  60             <xsl:value-of select="translate(., '&#xA0;&#x2026;', '')"/>
  61         </a>
  62         <xsl:text> </xsl:text>
  63     </xsl:template>
  64
  65     <!--
  66          These are links to pic.twitter.com, use the direct link for those
  67          too instead of the t.co redirections.
  68     -->
  69     <xsl:template match="a[@data-pre-embedded='true']">
  70         <!-- Prepend and append a white space for aestethic reasons -->
  71         <xsl:text> </xsl:text>
  72         <a>
  73             <xsl:attribute name="href">
  74                 <xsl:value-of select="concat('https://', .)"/>
  75             </xsl:attribute>
  76             <xsl:value-of select="concat('https://', .)"/>
  77         </a>
  78         <xsl:text> </xsl:text>
  79     </xsl:template>
  80
  81     <!-- Present images in a more convenient way -->
  82     <xsl:template match="div[@data-image-url]">
  83         <a>
  84             <xsl:attribute name="href">
  85                 <xsl:value-of select="concat(@data-image-url, ':orig')"/>
  86             </xsl:attribute>
  87             <img>
  88                 <xsl:attribute name="src">
  89                     <xsl:value-of select="@data-image-url"/>
  90                 </xsl:attribute>
  91             </img>
  92         </a>
  93     </xsl:template>
  94
  95     <xsl:template match="a[@data-expanded-url]" mode="enclosure">
  96         <xsl:copy-of select="php:function('Tweeper::generateEnclosure', string(./@data-expanded-url))"/>
  97     </xsl:template>
  98
  99     <xsl:variable name="screen-name" select="//div[@class='user-actions btn-group not-following ']/@data-screen-name"/>
 100
 101     <xsl:template match="//li[@data-item-id and @data-item-type='tweet']">
 102         <xsl:variable name="user-name" select=".//div[contains(@class, 'js-stream-tweet')]/@data-screen-name"/>
 103         <xsl:variable name="item-content" select=".//p[contains(@class, 'js-tweet-text')]"/>
 104         <xsl:variable name="item-media" select=".//div[contains(@class, 'AdaptiveMedia-container')]"/>
 105         <xsl:variable name="item-permalink" select="concat($BaseURL, .//div[@data-permalink-path]/@data-permalink-path)"/>
 106         <item>
 107             <title>
 108                 <xsl:value-of select="concat($user-name, ': ')"/>
 109                 <!--
 110                      Prepend a space in front of the URLs which are not
 111                      preceded by an open parenthesis, for aestethic reasons.
 112                      Also, regex, I know: http://xkcd.com/1171/
 113                 -->
 114                 <xsl:variable
 115                     name="processed-title"
 116                     select="php:function('preg_replace', '@((?&lt;!\()(?:http[s]?://|pic.twitter.com))@', ' \1', string($item-content))"/>
 117                 <!-- Also strip &nbsp; and &hellip; -->
 118                 <xsl:value-of select="normalize-space(translate($processed-title, '&#xA0;&#x2026;', ''))"/>
 119             </title>
 120             <link>
 121                 <xsl:value-of select="$item-permalink"/>
 122             </link>
 123             <guid>
 124                 <xsl:value-of select="$item-permalink"/>
 125             </guid>
 126             <pubDate>
 127                 <xsl:variable name="timestamp" select=".//span[contains(@class, 'js-short-timestamp')]/@data-time"/>
 128                 <xsl:value-of select="php:functionString('Tweeper::epochToRssDate', number($timestamp))"/>
 129             </pubDate>
 130             <description>
 131                 <xsl:value-of select="concat($user-name, ': ')"/>
 132                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 133                 <xsl:apply-templates select="$item-content/node()"/>
 134                 <xsl:apply-templates select="$item-media/node()"/>
 135                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 136             </description>
 137             <xsl:if test="$generate-enclosure = 1">
 138                 <xsl:apply-templates select="$item-content//a[@data-expanded-url]" mode="enclosure"/>
 139             </xsl:if>
 140         </item>
 141     </xsl:template>
 142
 143     <xsl:template match="/">
 144         <xsl:variable name="channel-title">
 145             <xsl:choose>
 146                 <xsl:when test="$screen-name != ''">
 147                     <xsl:value-of select="concat('Twitter / ', $screen-name)"/>
 148                 </xsl:when>
 149                 <xsl:otherwise>
 150                     <xsl:value-of select="concat('Twitter / ', normalize-space(//h1[1]))"/>
 151                 </xsl:otherwise>
 152             </xsl:choose>
 153         </xsl:variable>
 154         <xsl:variable name="channel-link" select="//link[@rel='canonical']/@href"/>
 155
 156         <rss version="2.0">
 157             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 158             <channel>
 159                 <generator>Tweeper</generator>
 160                 <title>
 161                     <xsl:value-of select="$channel-title"/>
 162                 </title>
 163                 <link>
 164                     <xsl:value-of select="$channel-link"/>
 165                 </link>
 166                 <description>
 167                     <xsl:value-of select="normalize-space(//div[@class='ProfileHeaderCard'])"/>
 168                 </description>
 169                 <image>
 170                     <title>
 171                         <xsl:value-of select="$channel-title"/>
 172                     </title>
 173                     <link>
 174                         <xsl:value-of select="$channel-link"/>
 175                     </link>
 176                     <url>
 177                         <xsl:value-of select="//a[contains(@class, 'profile-picture')]/@href"/>
 178                     </url>
 179                 </image>
 180                 <xsl:apply-templates select="//ol[@id='stream-items-id']/li[@data-item-id and @data-item-type='tweet']"/>
 181             </channel>
 182         </rss>
 183     </xsl:template>
 184 </xsl:stylesheet>