src/rss_converter_twitter.com.xsl

   1 <!--
   2   Stylesheet to convert Twitter user timelines to RSS.
   3
   4   Copyright (C) 2013-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://twitter.com</xsl:text>
  33     </xsl:variable>
  34
  35     <!-- Identity transform -->
  36     <xsl:template match="@*|node()">
  37         <xsl:copy>
  38             <!--
  39                 Strip the style attribute while copying elements because it may be
  40                 dangerous, see:
  41                 https://validator.w3.org/feed/docs/warning/DangerousStyleAttr.html
  42             -->
  43             <xsl:apply-templates select="@*[not(name() = 'style')]|node()"/>
  44         </xsl:copy>
  45     </xsl:template>
  46
  47     <!--
  48          Anchors to external links provide the direct URL in the
  49          data-expanded-url attribute, so use this in the href attribute too
  50          instead of the default short URL which uses the t.co redirection
  51          service.
  52
  53          NOTE: when creating an element, attributes must be processed _before_
  54          adding the contents (either children or a value):
  55          http://stackoverflow.com/questions/21984867/
  56     -->
  57     <xsl:template match="a[@data-expanded-url]">
  58         <!-- Prepend and append a white space for aestethic reasons -->
  59         <xsl:text> </xsl:text>
  60         <a>
  61             <xsl:attribute name="href">
  62                 <xsl:value-of select="@data-expanded-url"/>
  63             </xsl:attribute>
  64             <!-- Also strip &nbsp; and &hellip; -->
  65             <xsl:value-of select="translate(., '&#xA0;&#x2026;', '')"/>
  66         </a>
  67         <xsl:text> </xsl:text>
  68     </xsl:template>
  69
  70     <!--
  71          These are links to pic.twitter.com, use the direct link for those
  72          too instead of the t.co redirections.
  73     -->
  74     <xsl:template match="a[@data-pre-embedded='true']">
  75         <!-- Prepend and append a white space for aestethic reasons -->
  76         <xsl:text> </xsl:text>
  77         <a>
  78             <xsl:attribute name="href">
  79                 <xsl:value-of select="concat('https://', .)"/>
  80             </xsl:attribute>
  81             <xsl:value-of select="concat('https://', .)"/>
  82         </a>
  83         <xsl:text> </xsl:text>
  84     </xsl:template>
  85
  86     <!-- Present images in a more convenient way -->
  87     <xsl:template match="div[@data-image-url]">
  88         <a>
  89             <xsl:attribute name="href">
  90                 <xsl:value-of select="concat(@data-image-url, ':orig')"/>
  91             </xsl:attribute>
  92             <img style="max-width: 100%">
  93                 <xsl:attribute name="src">
  94                     <xsl:value-of select="@data-image-url"/>
  95                 </xsl:attribute>
  96             </img>
  97         </a>
  98     </xsl:template>
  99
 100     <!-- Don't repeat background in embedded media content -->
 101     <xsl:template match="div[contains(@class, 'PlayableMedia-player')]">
 102         <xsl:copy>
 103             <xsl:apply-templates select="@*"/>
 104             <xsl:attribute name="style">
 105                 <xsl:value-of select="concat(@style, '; background-repeat: no-repeat; background-size: 100% auto')"/>
 106             </xsl:attribute>
 107             <xsl:apply-templates select="node()"/>
 108         </xsl:copy>
 109     </xsl:template>
 110
 111     <xsl:template match="a[@data-expanded-url]" mode="enclosure">
 112         <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', ./@data-expanded-url)"/>
 113     </xsl:template>
 114
 115     <xsl:template match="div[@data-image-url]" mode="enclosure">
 116         <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', concat(./@data-image-url, ':orig'))"/>
 117     </xsl:template>
 118
 119     <xsl:variable name="screen-name" select="//div[@class='user-actions btn-group not-following ']/@data-screen-name"/>
 120
 121     <xsl:template match="//div[@class='permalink-inner permalink-tweet-container'] | //li[@data-item-id and @data-item-type='tweet']">
 122         <xsl:variable name="user-name" select=".//div[@data-tweet-id]/@data-screen-name"/>
 123         <xsl:variable name="item-content" select=".//p[contains(@class, 'js-tweet-text')]"/>
 124         <xsl:variable name="item-media" select=".//div[contains(@class, 'AdaptiveMedia-container')]"/>
 125         <xsl:variable name="item-permalink" select="concat($BaseURL, .//div[@data-permalink-path]/@data-permalink-path)"/>
 126
 127         <xsl:variable name="item-has-video" select="$item-media//*[contains(@class, 'PlayableMedia--video')]"/>
 128         <xsl:variable name="item-has-gif" select="$item-media//*[contains(@class, 'PlayableMedia--gif')]"/>
 129         <item>
 130             <title>
 131                 <xsl:value-of select="concat($user-name, ': ')"/>
 132                 <xsl:if test="$item-has-video">
 133                     <xsl:text>(Video) </xsl:text>
 134                 </xsl:if>
 135                 <!--
 136                      Prepend a space in front of the URLs which are not
 137                      preceded by an open parenthesis, for aestethic reasons.
 138                      Also, regex, I know: http://xkcd.com/1171/
 139                 -->
 140                 <xsl:variable
 141                     name="processed-title"
 142                     select="php:functionString('preg_replace', '@((?&lt;!\()(?:http[s]?://|pic.twitter.com))@', ' \1', $item-content)"/>
 143                 <!-- Also strip &nbsp; and &hellip; -->
 144                 <xsl:value-of select="normalize-space(translate($processed-title, '&#xA0;&#x2026;', ''))"/>
 145             </title>
 146             <link>
 147                 <xsl:value-of select="$item-permalink"/>
 148             </link>
 149             <guid>
 150                 <xsl:value-of select="$item-permalink"/>
 151             </guid>
 152             <pubDate>
 153                 <xsl:variable name="timestamp" select=".//span[contains(@class, 'js-short-timestamp')]/@data-time"/>
 154                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', number($timestamp))"/>
 155             </pubDate>
 156             <description>
 157                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 158                 <xsl:value-of select="concat($user-name, ':')"/>
 159                 <xsl:element name="br"/>
 160                 <xsl:if test="$item-has-video">
 161                     <xsl:text> (Video)</xsl:text>
 162                     <xsl:element name="br"/>
 163                 </xsl:if>
 164                 <xsl:if test="$item-has-gif">
 165                     <xsl:text> (GIF)</xsl:text>
 166                     <xsl:element name="br"/>
 167                 </xsl:if>
 168                 <xsl:element name="span">
 169                     <xsl:attribute name="style">white-space: pre-wrap;</xsl:attribute>
 170                     <xsl:apply-templates select="$item-content/node()"/>
 171                 </xsl:element>
 172                 <xsl:apply-templates select="$item-media/node()"/>
 173                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 174             </description>
 175             <xsl:if test="$generate-enclosure = 1">
 176                 <xsl:apply-templates select="$item-content//a[@data-expanded-url]" mode="enclosure"/>
 177                 <xsl:apply-templates select="$item-media//div[@data-image-url]" mode="enclosure"/>
 178             </xsl:if>
 179         </item>
 180     </xsl:template>
 181
 182     <xsl:template match="/">
 183         <xsl:variable name="channel-title">
 184             <xsl:choose>
 185                 <xsl:when test="$screen-name != ''">
 186                     <xsl:value-of select="concat('Twitter / ', $screen-name)"/>
 187                 </xsl:when>
 188                 <xsl:otherwise>
 189                     <xsl:value-of select="concat('Twitter / ', normalize-space(//h1[1]))"/>
 190                 </xsl:otherwise>
 191             </xsl:choose>
 192         </xsl:variable>
 193         <xsl:variable name="channel-link" select="//link[@rel='canonical']/@href"/>
 194         <xsl:variable name="channel-image" select="//a[contains(@class, 'profile-picture')]/@href"/>
 195
 196         <rss version="2.0">
 197             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 198             <channel>
 199                 <generator>Tweeper</generator>
 200                 <title>
 201                     <xsl:value-of select="$channel-title"/>
 202                 </title>
 203                 <link>
 204                     <xsl:value-of select="$channel-link"/>
 205                 </link>
 206                 <description>
 207                     <xsl:value-of select="normalize-space(//div[@class='ProfileHeaderCard'])"/>
 208                     <!-- The following rule should only match on hashtag URLs -->
 209                     <xsl:value-of select="normalize-space(//div[@class='SearchNavigation-textContainer'])"/>
 210                 </description>
 211                 <xsl:if test="$channel-image != ''">
 212                     <image>
 213                         <title>
 214                             <xsl:value-of select="$channel-title"/>
 215                         </title>
 216                         <link>
 217                             <xsl:value-of select="$channel-link"/>
 218                         </link>
 219                         <url>
 220                             <xsl:value-of select="$channel-image"/>
 221                         </url>
 222                     </image>
 223                 </xsl:if>
 224                 <xsl:apply-templates select="//ol[@id='stream-items-id']/li[@data-item-id and @data-item-type='tweet' and not(contains(@class, 'has-profile-promoted-tweet'))]"/>
 225
 226                 <!-- These rules will only match on permalink URLs -->
 227                 <xsl:apply-templates select="//div[@class='permalink-inner permalink-tweet-container']"/>
 228                 <xsl:apply-templates select="//div[@data-component-context='replies']//li[@data-item-id and @data-item-type='tweet' and not(contains(@class, 'has-profile-promoted-tweet'))]"/>
 229
 230             </channel>
 231         </rss>
 232     </xsl:template>
 233 </xsl:stylesheet>