src/rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     exclude-result-prefixes="php">
  25
  26     <xsl:param name="generate-enclosure"/>
  27     <xsl:param name="show-usernames"/>
  28     <xsl:param name="show-multimedia"/>
  29
  30     <xsl:output method="xml" indent="yes"/>
  31
  32     <xsl:variable name="BaseURL">
  33         <xsl:text>https://instagram.com</xsl:text>
  34     </xsl:variable>
  35
  36     <xsl:variable name="user-name" select="//ProfilePage/graphql/user/username"/>
  37
  38     <!--
  39          NOTE: some users do not specify the full name.
  40
  41          Remember to handle this case when using it and fall-back to the plain
  42          user name when appropriate.
  43     -->
  44     <xsl:variable name="full-name" select="//ProfilePage/graphql/user/full_name"/>
  45
  46     <xsl:variable name="location-name" select="//LocationsPage/graphql/location/name"/>
  47
  48     <xsl:variable name="hashtag-name" select="//TagPage/graphql/hashtag/name"/>
  49
  50     <xsl:variable name="screen-name">
  51         <xsl:choose>
  52             <xsl:when test="$location-name != ''">
  53                 <xsl:value-of select="$location-name"/>
  54             </xsl:when>
  55             <xsl:when test="$hashtag-name != ''">
  56                 <xsl:value-of select="$hashtag-name"/>
  57             </xsl:when>
  58             <xsl:when test="$full-name != ''">
  59                 <xsl:value-of select="$full-name"/>
  60             </xsl:when>
  61             <xsl:otherwise>
  62                 <xsl:value-of select="$user-name"/>
  63             </xsl:otherwise>
  64         </xsl:choose>
  65     </xsl:variable>
  66
  67     <xsl:template match="//edges/node">
  68         <xsl:variable name="item-content-image" select="./display_url"/>
  69         <xsl:variable name="item-content-image-data" select="php:functionString('Tweeper\Tweeper::generateDataURL', $item-content-image)"/>
  70         <xsl:variable name="item-content-caption" select="./edge_media_to_caption/edges/node/text"/>
  71         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./shortcode, '/')"/>
  72         <item>
  73             <title>
  74                 <xsl:variable name="title-length" select="140"/>
  75                 <xsl:variable name="item-content-title">
  76                     <xsl:if test="$show-usernames = 1">
  77                         <xsl:value-of select="concat($screen-name, ': ')"/>
  78                     </xsl:if>
  79                     <xsl:value-of select="normalize-space($item-content-caption)"/>
  80                 </xsl:variable>
  81                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  82                 <xsl:choose>
  83                     <xsl:when test="string-length($item-content-title) > $title-length">
  84                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  85                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  86                         <xsl:text>...</xsl:text>
  87                     </xsl:when>
  88                     <xsl:otherwise>
  89                         <xsl:value-of select="$item-content-title"/>
  90                     </xsl:otherwise>
  91                 </xsl:choose>
  92             </title>
  93             <link>
  94                 <xsl:value-of select="$item-permalink"/>
  95             </link>
  96             <guid>
  97                 <xsl:value-of select="$item-permalink"/>
  98             </guid>
  99             <pubDate>
 100                 <xsl:variable name="timestamp" select="./taken_at_timestamp"/>
 101                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
 102             </pubDate>
 103             <description>
 104                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 105                 <p>
 106                     <xsl:if test="./is_video/text() = 1">
 107                         (Video)
 108                     </xsl:if>
 109                     <xsl:value-of select="$item-content-caption"/>
 110                 </p><br />
 111                 <xsl:if test="$show-multimedia = 1">
 112                     <a href="{$item-permalink}"><img src="{$item-content-image-data}" style="max-width: 100%"/></a>
 113                 </xsl:if>
 114                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 115             </description>
 116             <xsl:if test="$generate-enclosure = 1">
 117                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $item-content-image)"/>
 118             </xsl:if>
 119         </item>
 120     </xsl:template>
 121
 122     <xsl:template match="/">
 123
 124         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 125         <xsl:variable name="channel-link">
 126             <xsl:choose>
 127                 <xsl:when test="$location-name != ''">
 128                     <xsl:variable name="location-id" select="//LocationsPage/graphql/location/id"/>
 129                     <xsl:value-of select="concat($BaseURL, '/explore/locations/', $location-id)"/>
 130                 </xsl:when>
 131                 <xsl:when test="$hashtag-name != ''">
 132                     <xsl:value-of select="concat($BaseURL, '/explore/tags/', $hashtag-name)"/>
 133                 </xsl:when>
 134                 <xsl:otherwise>
 135                     <xsl:value-of select="concat($BaseURL, '/', $user-name)"/>
 136                 </xsl:otherwise>
 137             </xsl:choose>
 138         </xsl:variable>
 139         <xsl:variable name="channel-image" select="//profile_pic_url"/>
 140
 141         <rss version="2.0">
 142             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 143             <channel>
 144                 <generator>Tweeper</generator>
 145                 <title>
 146                     <xsl:value-of select="$channel-title"/>
 147                 </title>
 148                 <link>
 149                     <xsl:value-of select="$channel-link"/>
 150                 </link>
 151                 <description>
 152                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 153                     <xsl:choose>
 154                         <xsl:when test="$location-name != ''">
 155                             <xsl:variable name="location-latitude" select="//LocationsPage/graphql/location/lat"/>
 156                             <xsl:variable name="location-longitude" select="//LocationsPage/graphql/location/lng"/>
 157                             <xsl:value-of select="concat($location-name, ' (', $location-latitude, ', ', $location-longitude, ')')"/>
 158                         </xsl:when>
 159                         <xsl:when test="$hashtag-name != ''">
 160                             <xsl:value-of select="concat('#', $hashtag-name)"/>
 161                         </xsl:when>
 162                         <xsl:otherwise>
 163                             <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 164                             <xsl:variable name="external-url" select="//user/external_url"/>
 165                             <xsl:if test="$external-url != ''">
 166                                 <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 167                             </xsl:if>
 168                         </xsl:otherwise>
 169                     </xsl:choose>
 170                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 171                 </description>
 172                 <xsl:if test="$channel-image != ''">
 173                     <image>
 174                         <title>
 175                             <xsl:value-of select="$channel-title"/>
 176                         </title>
 177                         <link>
 178                             <xsl:value-of select="$channel-link"/>
 179                         </link>
 180                         <url>
 181                             <xsl:value-of select="$channel-image"/>
 182                         </url>
 183                     </image>
 184                 </xsl:if>
 185                 <xsl:apply-templates select="//ProfilePage/graphql/user/edge_owner_to_timeline_media/edges/node|//LocationsPage/graphql/location/edge_location_to_media/edges/node|//TagPage/graphql/hashtag/edge_hashtag_to_media/edges/node"/>
 186             </channel>
 187         </rss>
 188     </xsl:template>
 189 </xsl:stylesheet>