rss_converter_facebook.com.xsl

   1 <!--
   2   Stylesheet to convert a Facebook public page to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <!--
  23   Since June 23rd, 2015 facebook.com deprecated the RSS feed endpoint for public pages:
  24   https://developers.facebook.com/docs/apps/changelog#v2_3_90_day_deprecations
  25
  26   They suggest to use the Graph API but they fail to mention that it does not
  27   work anymore without authentication, so it cannot be considered an
  28   _equivalent_ solution.
  29
  30   Luckily we've got Tweeper!
  31 -->
  32
  33 <xsl:stylesheet version="1.0"
  34     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  35     xmlns:php="http://php.net/xsl"
  36     xsl:extension-element-prefixes="php"
  37     exclude-result-prefixes="php">
  38
  39     <xsl:output method="xml" indent="yes"/>
  40
  41     <xsl:variable name="BaseURL">
  42         <xsl:text>https://facebook.com</xsl:text>
  43     </xsl:variable>
  44
  45     <!--
  46          Extract the page id from an element like:
  47         <meta property="al:android:url" content="fb://page/793837197390834">
  48
  49         The page id will be used to build the permalink.
  50     -->
  51     <xsl:variable
  52         name="page-id"
  53         select="substring-after(//meta[@property='al:android:url']/@content, 'fb://page/')"/>
  54
  55     <xsl:template match="//div[contains(@class, 'userContentWrapper')]">
  56         <xsl:variable name="story-id" select=".//input[@name='ft_ent_identifier']/@value"/>
  57         <xsl:variable name="item-content" select=".//div[contains(@class, 'userContent')]"/>
  58         <xsl:variable
  59             name="item-permalink"
  60             select="concat($BaseURL, '/permalink.php?id=', $page-id, '&amp;story_fbid=', $story-id)"/>
  61
  62         <item>
  63             <title>
  64                 <xsl:variable name="item-title" select="$item-content/p"/>
  65                 <xsl:variable name="title-length" select="140"/>
  66                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  67                 <xsl:choose>
  68                     <xsl:when test="string-length($item-title) > $title-length">
  69                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  70                         <xsl:value-of select="substring($item-title, 1, $truncated-length)"/>
  71                         <xsl:text>...</xsl:text>
  72                     </xsl:when>
  73                     <xsl:otherwise>
  74                         <xsl:value-of select="$item-title"/>
  75                     </xsl:otherwise>
  76                 </xsl:choose>
  77             </title>
  78             <link>
  79                 <xsl:value-of select="$item-permalink"/>
  80             </link>
  81             <guid>
  82                 <xsl:value-of select="$item-permalink"/>
  83             </guid>
  84             <pubDate>
  85                 <xsl:variable name="timestamp" select=".//abbr[@data-shorten]/@data-utime"/>
  86                 <xsl:value-of select="php:functionString('Tweeper::epoch_to_gmdate', number($timestamp))"/>
  87             </pubDate>
  88             <description>
  89                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  90                 <xsl:copy-of select="$item-content/node()"/>
  91                 <xsl:copy-of select=".//div[@class='mtm']/node()"/>
  92                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  93             </description>
  94         </item>
  95     </xsl:template>
  96
  97     <xsl:template match="/">
  98         <xsl:variable name="channel-title" select="//title"/>
  99         <xsl:variable name="channel-link" select="//div[contains(@class, 'userContentWrapper')][1]//a[1]/@href"/>
 100
 101         <rss version="2.0">
 102             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 103             <channel>
 104                 <generator>Tweeper</generator>
 105                 <title>
 106                     <xsl:value-of select="$channel-title"/>
 107                 </title>
 108                 <link>
 109                     <xsl:value-of select="$channel-link"/>
 110                 </link>
 111                 <description>
 112                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 113                     <xsl:copy-of select="//div[@data-id='1']/node()"/>
 114                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 115                 </description>
 116                 <image>
 117                     <title>
 118                         <xsl:value-of select="$channel-title"/>
 119                     </title>
 120                     <link>
 121                         <xsl:value-of select="$channel-link"/>
 122                     </link>
 123                     <url>
 124                         <xsl:value-of select="//img[@class='profilePic img']/@src"/>
 125                     </url>
 126                 </image>
 127                 <xsl:apply-templates select="//div[contains(@class, 'userContentWrapper')]"/>
 128             </channel>
 129         </rss>
 130     </xsl:template>
 131 </xsl:stylesheet>