rss_converter_twitter.com.xsl

   1 <!--
   2   Stylesheet to convert Twitter user timelines to RSS.
   3
   4   Copyright (C) 2013-2014  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generateEnclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://twitter.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:template match="a[@data-expanded-url]">
  36         <xsl:value-of disable-output-escaping="yes" select="php:function('Tweeper::generate_enclosure', string(./@data-expanded-url))"/>
  37     </xsl:template>
  38
  39     <xsl:variable name="screen-name" select="//div[@class='user-actions btn-group not-following ']/@data-screen-name"/>
  40
  41     <xsl:template match="//*[@data-item-type='tweet' and @role='listitem']">
  42         <xsl:variable name="user-name" select=".//div[contains(@class, 'js-stream-tweet')]/@data-screen-name"/>
  43         <xsl:variable name="item-content" select=".//p[contains(@class, 'js-tweet-text')]"/>
  44         <xsl:variable name="item-permalink" select="concat($BaseURL, .//div[@data-permalink-path]/@data-permalink-path)"/>
  45         <item>
  46             <title>
  47                 <xsl:value-of select="concat($user-name, ': ', $item-content)"/>
  48             </title>
  49             <link>
  50                 <xsl:value-of select="$item-permalink"/>
  51             </link>
  52             <guid>
  53                 <xsl:value-of select="$item-permalink"/>
  54             </guid>
  55             <pubDate>
  56                 <xsl:variable name="timestamp" select=".//span[contains(@class, 'js-short-timestamp')]/@data-time"/>
  57                 <xsl:value-of select="php:functionString('Tweeper::epoch_to_gmdate', number($timestamp))"/>
  58             </pubDate>
  59             <description>
  60                 <xsl:value-of select="concat($user-name, ': ')"/>
  61                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  62                 <xsl:copy-of select="$item-content/node()"/>
  63                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  64             </description>
  65             <xsl:if test="$generateEnclosure = 1">
  66                 <xsl:apply-templates select="$item-content//a[@data-expanded-url]"/>
  67             </xsl:if>
  68         </item>
  69     </xsl:template>
  70
  71     <xsl:template match="/">
  72         <xsl:variable name="channel-title" select="concat('Twitter / ', $screen-name)"/>
  73         <xsl:variable name="channel-link" select="//link[@rel='canonical']/@href"/>
  74
  75         <rss version="2.0">
  76             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  77             <channel>
  78                 <generator>Tweeper</generator>
  79                 <title>
  80                     <xsl:value-of select="$channel-title"/>
  81                 </title>
  82                 <link>
  83                     <xsl:value-of select="$channel-link"/>
  84                 </link>
  85                 <description>
  86                     <xsl:value-of select="normalize-space(//div[@class='ProfileHeaderCard'])"/>
  87                 </description>
  88                 <image>
  89                     <title>
  90                         <xsl:value-of select="$channel-title"/>
  91                     </title>
  92                     <link>
  93                         <xsl:value-of select="$channel-link"/>
  94                     </link>
  95                     <url>
  96                         <xsl:value-of select="//a[contains(@class, 'profile-picture media-thumbnail')]/@href"/>
  97                     </url>
  98                 </image>
  99                 <xsl:apply-templates select="//*[@data-item-type='tweet' and @role='listitem']"/>
 100             </channel>
 101         </rss>
 102     </xsl:template>
 103 </xsl:stylesheet>