rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generateEnclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:template match="display_src">
  36         <xsl:value-of disable-output-escaping="yes" select="php:function('Tweeper::generate_enclosure', string(text()))"/>
  37     </xsl:template>
  38
  39     <xsl:variable name="screen-name" select="//ProfilePage/XML_Serializer_Tag/user/full_name"/>
  40     <xsl:variable name="user-name" select="//ProfilePage/XML_Serializer_Tag/user/username"/>
  41
  42     <xsl:template match="//media/nodes/XML_Serializer_Tag">
  43         <xsl:variable name="item-content-image" select="./display_src"/>
  44         <xsl:variable name="item-content-caption" select="./caption"/>
  45         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./code, '/')"/>
  46         <item>
  47             <title>
  48                 <xsl:variable name="title-length" select="140"/>
  49                 <xsl:variable name="item-content-title" select="normalize-space(concat($user-name, ': ', $item-content-caption))"/>
  50                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  51                 <xsl:choose>
  52                     <xsl:when test="string-length($item-content-title) > $title-length">
  53                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  54                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  55                         <xsl:text>...</xsl:text>
  56                     </xsl:when>
  57                     <xsl:otherwise>
  58                         <xsl:value-of select="$item-content-title"/>
  59                     </xsl:otherwise>
  60                 </xsl:choose>
  61             </title>
  62             <link>
  63                 <xsl:value-of select="$item-permalink"/>
  64             </link>
  65             <guid>
  66                 <xsl:value-of select="$item-permalink"/>
  67             </guid>
  68             <pubDate>
  69                 <xsl:variable name="timestamp" select="./date"/>
  70                 <xsl:value-of select="php:functionString('Tweeper::epoch_to_gmdate', number($timestamp))"/>
  71             </pubDate>
  72             <description>
  73                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  74                 <p>
  75                     <xsl:if test="./is_video/text() = 1">
  76                         (Video)
  77                     </xsl:if>
  78                     <xsl:value-of select="$item-content-caption"/>
  79                 </p><br />
  80                 <a href="{$item-permalink}"><img src="{$item-content-image}" /></a>
  81                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  82             </description>
  83             <xsl:if test="$generateEnclosure = 1">
  84                 <xsl:apply-templates select="./display_src"/>
  85             </xsl:if>
  86         </item>
  87     </xsl:template>
  88
  89     <xsl:template match="/">
  90         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
  91         <xsl:variable name="channel-link" select="concat($BaseURL, //__path)"/>
  92
  93         <rss version="2.0">
  94             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  95             <channel>
  96                 <generator>Tweeper</generator>
  97                 <title>
  98                     <xsl:value-of select="$channel-title"/>
  99                 </title>
 100                 <link>
 101                     <xsl:value-of select="$channel-link"/>
 102                 </link>
 103                 <description>
 104                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 105                     <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 106                     <xsl:variable name="external-url" select="//user/external_url"/>
 107                     <xsl:if test="$external-url != ''">
 108                         <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 109                     </xsl:if>
 110                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 111                 </description>
 112                 <image>
 113                     <title>
 114                         <xsl:value-of select="$channel-title"/>
 115                     </title>
 116                     <link>
 117                         <xsl:value-of select="$channel-link"/>
 118                     </link>
 119                     <url>
 120                         <xsl:value-of select="//user/profile_pic_url"/>
 121                     </url>
 122                 </image>
 123                 <xsl:apply-templates select="//media/nodes/XML_Serializer_Tag"/>
 124             </channel>
 125         </rss>
 126     </xsl:template>
 127 </xsl:stylesheet>