src/rss_converter_facebook.com.xsl

   1 <!--
   2   Stylesheet to convert a Facebook public page to RSS.
   3
   4   Copyright (C) 2015-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <!--
  23   Since June 23rd, 2015 facebook.com deprecated the RSS feed endpoint for public pages:
  24   https://developers.facebook.com/docs/apps/changelog#v2_3_90_day_deprecations
  25
  26   They suggest to use the Graph API but they fail to mention that it does not
  27   work anymore without authentication, so it cannot be considered an
  28   _equivalent_ solution.
  29
  30   Luckily we've got Tweeper!
  31 -->
  32
  33 <xsl:stylesheet version="1.0"
  34     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  35     xmlns:php="http://php.net/xsl"
  36     exclude-result-prefixes="php">
  37
  38     <xsl:output method="xml" indent="yes"/>
  39
  40     <xsl:variable name="BaseURL">
  41         <xsl:text>https://facebook.com</xsl:text>
  42     </xsl:variable>
  43
  44     <!--
  45          Extract the page id from an element like:
  46         <meta property="al:android:url" content="fb://page/793837197390834">
  47
  48         The page id will be used to build the permalink.
  49     -->
  50     <xsl:variable
  51         name="page-id"
  52         select="substring-after(//meta[@property='al:android:url']/@content, 'fb://page/')"/>
  53
  54     <xsl:template match="//div[contains(@class, 'fbUserStory') or contains(@class, 'userContentWrapper')]">
  55         <xsl:variable name="story-id" select=".//input[@name='ft_ent_identifier']/@value"/>
  56         <xsl:variable
  57             name="item-permalink"
  58             select="concat($BaseURL, '/permalink.php?id=', $page-id, '&amp;story_fbid=', $story-id)"/>
  59
  60         <!-- Get only the first child in order to skip the footer of the content -->
  61         <xsl:variable name="item-content" select="div[1]"/>
  62
  63         <item>
  64             <title>
  65                 <xsl:variable name="item-title" select="$item-content//p"/>
  66                 <xsl:variable name="title-length" select="140"/>
  67                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  68                 <xsl:choose>
  69                     <xsl:when test="string-length($item-title) > $title-length">
  70                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  71                         <xsl:value-of select="substring($item-title, 1, $truncated-length)"/>
  72                         <xsl:text>...</xsl:text>
  73                     </xsl:when>
  74                     <xsl:otherwise>
  75                         <xsl:value-of select="$item-title"/>
  76                     </xsl:otherwise>
  77                 </xsl:choose>
  78             </title>
  79             <link>
  80                 <xsl:value-of select="$item-permalink"/>
  81             </link>
  82             <guid>
  83                 <xsl:value-of select="$item-permalink"/>
  84             </guid>
  85             <pubDate>
  86                 <xsl:variable name="timestamp" select=".//abbr[@data-shorten]/@data-utime"/>
  87                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
  88             </pubDate>
  89             <description>
  90
  91                 <!--
  92                      Get only the children starting from the one with class="userContent",
  93                      this way the content header is skipped
  94                 -->
  95                 <xsl:variable
  96                     name="usercontent-position"
  97                     select="count($item-content/div[contains(@class, 'userContent')]/preceding-sibling::*) + 1"/>
  98
  99                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 100                 <xsl:copy-of select="$item-content/div[position() >= $usercontent-position]"/>
 101                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 102             </description>
 103         </item>
 104     </xsl:template>
 105
 106     <xsl:template match="/">
 107         <xsl:variable name="channel-title" select="//title"/>
 108         <xsl:variable name="channel-link" select="//meta[@property='og:url']/@content"/>
 109         <xsl:variable name="channel-image" select="//meta[@property='og:image']/@content"/>
 110
 111         <rss version="2.0">
 112             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 113             <channel>
 114                 <generator>Tweeper</generator>
 115                 <title>
 116                     <xsl:value-of select="$channel-title"/>
 117                 </title>
 118                 <link>
 119                     <xsl:value-of select="$channel-link"/>
 120                 </link>
 121                 <description>
 122                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 123                     <xsl:value-of select="//meta[@property='og:description']/@content"/>
 124                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 125                 </description>
 126                 <image>
 127                     <title>
 128                         <xsl:value-of select="$channel-title"/>
 129                     </title>
 130                     <link>
 131                         <xsl:value-of select="$channel-link"/>
 132                     </link>
 133                     <url>
 134                         <xsl:value-of select="$channel-image"/>
 135                     </url>
 136                 </image>
 137                 <xsl:apply-templates select="//div[contains(@class, 'fbUserStory') or contains(@class, 'userContentWrapper')]"/>
 138             </channel>
 139         </rss>
 140     </xsl:template>
 141 </xsl:stylesheet>