rss_converter_dilbert.com.xsl

   1 <!--
   2   Stylesheet to convert Dilbert daily strips to RSS.
   3
   4   Copyright (C) 2013-2014  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <!--
  23   Since June 18, 2013 dilbert.com strips are not accessible anymore
  24   directly from the RSS feed, this message is displayed instead:
  25
  26     Dilbert readers - Please visit Dilbert.com to read this feature. Due
  27     to changes with our feeds, we are now making this RSS feed a link to
  28     Dilbert.com.
  29
  30   How unhandy is that, was it because of a management decision?
  31   Maybe a parody dilbert strip is needed about this issue...
  32 -->
  33
  34 <xsl:stylesheet version="1.0"
  35     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  36     xmlns:php="http://php.net/xsl"
  37     xsl:extension-element-prefixes="php"
  38     exclude-result-prefixes="php">
  39
  40     <xsl:output method="xml" indent="yes"/>
  41
  42     <xsl:variable name="BaseURL" select="//meta[@property='og:url']/@content"/>
  43
  44     <xsl:template match="//section[@class='comic-item']">
  45         <xsl:variable name="item-permalink" select=".//a[@class='img-comic-link']/@href"/>
  46         <xsl:variable name="picture-url" select=".//img[@class='img-responsive img-comic']/@src"/>
  47         <xsl:variable name="picture-title" select=".//img[@class='img-responsive img-comic']/@alt"/>
  48         <item>
  49             <title>
  50                 <xsl:value-of select="$picture-title"/>
  51             </title>
  52             <link>
  53                 <xsl:value-of select="$item-permalink"/>
  54             </link>
  55             <guid>
  56                 <xsl:value-of select="$item-permalink"/>
  57             </guid>
  58             <pubDate>
  59                 <xsl:value-of select="php:functionString('Tweeper::str_to_gmdate', normalize-space(.//date))"/>
  60             </pubDate>
  61             <description>
  62                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  63                 <img src="{$picture-url}" />
  64                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  65             </description>
  66         </item>
  67     </xsl:template>
  68
  69     <xsl:template match="/">
  70         <xsl:variable name="channel-title" select="//meta[@property='og:title']/@content"/>
  71         <xsl:variable name="channel-link" select="$BaseURL"/>
  72
  73         <rss version="2.0">
  74             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  75             <channel>
  76                 <generator>Tweeper</generator>
  77                 <title>
  78                     <xsl:value-of select="$channel-title"/>
  79                 </title>
  80                 <link>
  81                     <xsl:value-of select="$channel-link"/>
  82                 </link>
  83                 <description>
  84                     <xsl:value-of select="//meta[@property='og:description']/@content"/>
  85                 </description>
  86                 <image>
  87                     <title>
  88                         <xsl:value-of select="$channel-title"/>
  89                     </title>
  90                     <link>
  91                         <xsl:value-of select="$channel-link"/>
  92                     </link>
  93                     <url>
  94                         <xsl:value-of select="concat($BaseURL, //img[@alt='Dilbert logo']/@src)"/>
  95                     </url>
  96                 </image>
  97                 <xsl:apply-templates select="//section[@class='comic-item']"/>
  98             </channel>
  99         </rss>
 100     </xsl:template>
 101 </xsl:stylesheet>