src/rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     exclude-result-prefixes="php">
  25
  26     <xsl:param name="generate-enclosure"/>
  27     <xsl:param name="show-usernames"/>
  28     <xsl:param name="show-multimedia"/>
  29
  30     <xsl:output method="xml" indent="yes"/>
  31
  32     <xsl:variable name="BaseURL">
  33         <xsl:text>https://instagram.com</xsl:text>
  34     </xsl:variable>
  35
  36     <xsl:variable name="user-name" select="//ProfilePage/graphql/user/username"/>
  37
  38     <!--
  39          NOTE: some users do not specify the full name.
  40
  41          Remember to handle this case when using it and fall-back to the plain
  42          user name when appropriate.
  43     -->
  44     <xsl:variable name="full-name" select="//ProfilePage/graphql/user/full_name"/>
  45
  46     <xsl:variable name="location-name" select="//LocationsPage/graphql/location/name"/>
  47
  48     <xsl:variable name="hashtag-name" select="//TagPage/graphql/hashtag/name"/>
  49
  50     <xsl:variable name="screen-name">
  51         <xsl:choose>
  52             <xsl:when test="$location-name != ''">
  53                 <xsl:value-of select="$location-name"/>
  54             </xsl:when>
  55             <xsl:when test="$hashtag-name != ''">
  56                 <xsl:value-of select="$hashtag-name"/>
  57             </xsl:when>
  58             <xsl:when test="$full-name != ''">
  59                 <xsl:value-of select="$full-name"/>
  60             </xsl:when>
  61             <xsl:otherwise>
  62                 <xsl:value-of select="$user-name"/>
  63             </xsl:otherwise>
  64         </xsl:choose>
  65     </xsl:variable>
  66
  67     <xsl:template match="//edges/node">
  68         <xsl:variable name="item-content-image" select="./display_url"/>
  69         <xsl:variable name="item-content-caption" select="./edge_media_to_caption/edges/node/text"/>
  70         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./shortcode, '/')"/>
  71         <item>
  72             <title>
  73                 <xsl:variable name="title-length" select="140"/>
  74                 <xsl:variable name="item-content-title">
  75                     <xsl:if test="$show-usernames = 1">
  76                         <xsl:value-of select="concat($screen-name, ': ')"/>
  77                     </xsl:if>
  78                     <xsl:value-of select="normalize-space($item-content-caption)"/>
  79                 </xsl:variable>
  80                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  81                 <xsl:choose>
  82                     <xsl:when test="string-length($item-content-title) > $title-length">
  83                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  84                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  85                         <xsl:text>...</xsl:text>
  86                     </xsl:when>
  87                     <xsl:otherwise>
  88                         <xsl:value-of select="$item-content-title"/>
  89                     </xsl:otherwise>
  90                 </xsl:choose>
  91             </title>
  92             <link>
  93                 <xsl:value-of select="$item-permalink"/>
  94             </link>
  95             <guid>
  96                 <xsl:value-of select="$item-permalink"/>
  97             </guid>
  98             <pubDate>
  99                 <xsl:variable name="timestamp" select="./taken_at_timestamp"/>
 100                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
 101             </pubDate>
 102             <description>
 103                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 104                 <p>
 105                     <xsl:if test="./is_video/text() = 1">
 106                         (Video)
 107                     </xsl:if>
 108                     <xsl:value-of select="$item-content-caption"/>
 109                 </p><br />
 110                 <xsl:if test="$show-multimedia = 1">
 111                     <a href="{$item-permalink}"><img src="{$item-content-image}" style="max-width: 100%"/></a>
 112                 </xsl:if>
 113                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 114             </description>
 115             <xsl:if test="$generate-enclosure = 1">
 116                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $item-content-image)"/>
 117             </xsl:if>
 118         </item>
 119     </xsl:template>
 120
 121     <xsl:template match="/">
 122
 123         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 124         <xsl:variable name="channel-link">
 125             <xsl:choose>
 126                 <xsl:when test="$location-name != ''">
 127                     <xsl:variable name="location-id" select="//LocationsPage/graphql/location/id"/>
 128                     <xsl:value-of select="concat($BaseURL, '/explore/locations/', $location-id)"/>
 129                 </xsl:when>
 130                 <xsl:when test="$hashtag-name != ''">
 131                     <xsl:value-of select="concat($BaseURL, '/explore/tags/', $hashtag-name)"/>
 132                 </xsl:when>
 133                 <xsl:otherwise>
 134                     <xsl:value-of select="concat($BaseURL, '/', $user-name)"/>
 135                 </xsl:otherwise>
 136             </xsl:choose>
 137         </xsl:variable>
 138         <xsl:variable name="channel-image" select="//profile_pic_url"/>
 139
 140         <rss version="2.0">
 141             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 142             <channel>
 143                 <generator>Tweeper</generator>
 144                 <title>
 145                     <xsl:value-of select="$channel-title"/>
 146                 </title>
 147                 <link>
 148                     <xsl:value-of select="$channel-link"/>
 149                 </link>
 150                 <description>
 151                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 152                     <xsl:choose>
 153                         <xsl:when test="$location-name != ''">
 154                             <xsl:variable name="location-latitude" select="//LocationsPage/graphql/location/lat"/>
 155                             <xsl:variable name="location-longitude" select="//LocationsPage/graphql/location/lng"/>
 156                             <xsl:value-of select="concat($location-name, ' (', $location-latitude, ', ', $location-longitude, ')')"/>
 157                         </xsl:when>
 158                         <xsl:when test="$hashtag-name != ''">
 159                             <xsl:value-of select="concat('#', $hashtag-name)"/>
 160                         </xsl:when>
 161                         <xsl:otherwise>
 162                             <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 163                             <xsl:variable name="external-url" select="//user/external_url"/>
 164                             <xsl:if test="$external-url != ''">
 165                                 <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 166                             </xsl:if>
 167                         </xsl:otherwise>
 168                     </xsl:choose>
 169                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 170                 </description>
 171                 <xsl:if test="$channel-image != ''">
 172                     <image>
 173                         <title>
 174                             <xsl:value-of select="$channel-title"/>
 175                         </title>
 176                         <link>
 177                             <xsl:value-of select="$channel-link"/>
 178                         </link>
 179                         <url>
 180                             <xsl:value-of select="$channel-image"/>
 181                         </url>
 182                     </image>
 183                 </xsl:if>
 184                 <xsl:apply-templates select="//ProfilePage/graphql/user/edge_owner_to_timeline_media/edges/node|//LocationsPage/graphql/location/edge_location_to_media/edges/node|//TagPage/graphql/hashtag/edge_hashtag_to_media/edges/node"/>
 185             </channel>
 186         </rss>
 187     </xsl:template>
 188 </xsl:stylesheet>