rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:variable name="user-name" select="//ProfilePage/user/username"/>
  36
  37     <!-- Some users do not specify the full name -->
  38     <xsl:variable name="full-name" select="//ProfilePage/user/full_name"/>
  39     <xsl:variable name="screen-name">
  40         <xsl:choose>
  41             <xsl:when test="$full-name != ''">
  42                 <xsl:value-of select="$full-name"/>
  43             </xsl:when>
  44             <xsl:otherwise>
  45                 <xsl:value-of select="$user-name"/>
  46             </xsl:otherwise>
  47         </xsl:choose>
  48     </xsl:variable>
  49
  50     <xsl:template match="//ProfilePage/user/media/nodes">
  51         <xsl:variable name="item-content-image" select="./display_src"/>
  52         <xsl:variable name="item-content-caption" select="./caption"/>
  53         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./code, '/')"/>
  54         <item>
  55             <title>
  56                 <xsl:variable name="title-length" select="140"/>
  57                 <xsl:variable name="item-content-title" select="normalize-space(concat($user-name, ': ', $item-content-caption))"/>
  58                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  59                 <xsl:choose>
  60                     <xsl:when test="string-length($item-content-title) > $title-length">
  61                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  62                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  63                         <xsl:text>...</xsl:text>
  64                     </xsl:when>
  65                     <xsl:otherwise>
  66                         <xsl:value-of select="$item-content-title"/>
  67                     </xsl:otherwise>
  68                 </xsl:choose>
  69             </title>
  70             <link>
  71                 <xsl:value-of select="$item-permalink"/>
  72             </link>
  73             <guid>
  74                 <xsl:value-of select="$item-permalink"/>
  75             </guid>
  76             <pubDate>
  77                 <xsl:variable name="timestamp" select="./date"/>
  78                 <xsl:value-of select="php:functionString('Tweeper::epochToRssDate', $timestamp)"/>
  79             </pubDate>
  80             <description>
  81                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  82                 <p>
  83                     <xsl:if test="./is_video/text() = 1">
  84                         (Video)
  85                     </xsl:if>
  86                     <xsl:value-of select="$item-content-caption"/>
  87                 </p><br />
  88                 <a href="{$item-permalink}"><img src="{$item-content-image}" style="max-width: 100%"/></a>
  89                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  90             </description>
  91             <xsl:if test="$generate-enclosure = 1">
  92                 <xsl:copy-of select="php:functionString('Tweeper::generateEnclosure', $item-content-image)"/>
  93             </xsl:if>
  94         </item>
  95     </xsl:template>
  96
  97     <xsl:template match="/">
  98         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
  99         <xsl:variable name="channel-link" select="concat($BaseURL, '/', $user-name)"/>
 100
 101         <rss version="2.0">
 102             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 103             <channel>
 104                 <generator>Tweeper</generator>
 105                 <title>
 106                     <xsl:value-of select="$channel-title"/>
 107                 </title>
 108                 <link>
 109                     <xsl:value-of select="$channel-link"/>
 110                 </link>
 111                 <description>
 112                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 113                     <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 114                     <xsl:variable name="external-url" select="//user/external_url"/>
 115                     <xsl:if test="$external-url != ''">
 116                         <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 117                     </xsl:if>
 118                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 119                 </description>
 120                 <image>
 121                     <title>
 122                         <xsl:value-of select="$channel-title"/>
 123                     </title>
 124                     <link>
 125                         <xsl:value-of select="$channel-link"/>
 126                     </link>
 127                     <url>
 128                         <xsl:value-of select="//ProfilePage/user/profile_pic_url"/>
 129                     </url>
 130                 </image>
 131                 <xsl:apply-templates select="//ProfilePage/user/media/nodes"/>
 132             </channel>
 133         </rss>
 134     </xsl:template>
 135 </xsl:stylesheet>