rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generateEnclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:template match="display_src">
  36         <xsl:value-of disable-output-escaping="yes" select="php:function('Tweeper::generate_enclosure', string(text()))"/>
  37     </xsl:template>
  38
  39     <xsl:variable name="screen-name" select="//ProfilePage/XML_Serializer_Tag/user/full_name"/>
  40     <xsl:variable name="user-name" select="//ProfilePage/XML_Serializer_Tag/user/username"/>
  41
  42     <xsl:template match="//media/nodes/XML_Serializer_Tag">
  43         <xsl:variable name="item-content-image" select="./display_src"/>
  44         <xsl:variable name="item-content-caption" select="./caption"/>
  45         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./code, '/')"/>
  46         <item>
  47             <title>
  48                 <xsl:variable name="title-length" select="140"/>
  49                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  50                 <xsl:choose>
  51                     <xsl:when test="string-length($item-content-caption) > $title-length">
  52                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  53                         <xsl:value-of select="normalize-space(substring($item-content-caption, 1, $truncated-length))"/>
  54                         <xsl:text>...</xsl:text>
  55                     </xsl:when>
  56                     <xsl:otherwise>
  57                         <xsl:value-of select="normalize-space($item-content-caption)"/>
  58                     </xsl:otherwise>
  59                 </xsl:choose>
  60             </title>
  61             <link>
  62                 <xsl:value-of select="$item-permalink"/>
  63             </link>
  64             <guid>
  65                 <xsl:value-of select="$item-permalink"/>
  66             </guid>
  67             <pubDate>
  68                 <xsl:variable name="timestamp" select="./date"/>
  69                 <xsl:value-of select="php:functionString('Tweeper::epoch_to_gmdate', number($timestamp))"/>
  70             </pubDate>
  71             <description>
  72                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  73                 <p><xsl:value-of select="$item-content-caption"/></p><br />
  74                 <a href="{$item-permalink}"><img src="{$item-content-image}" /></a>
  75                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  76             </description>
  77             <xsl:if test="$generateEnclosure = 1">
  78                 <xsl:apply-templates select="./display_src"/>
  79             </xsl:if>
  80         </item>
  81     </xsl:template>
  82
  83     <xsl:template match="/">
  84         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
  85         <xsl:variable name="channel-link" select="concat($BaseURL, //__path)"/>
  86
  87         <rss version="2.0">
  88             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  89             <channel>
  90                 <generator>Tweeper</generator>
  91                 <title>
  92                     <xsl:value-of select="$channel-title"/>
  93                 </title>
  94                 <link>
  95                     <xsl:value-of select="$channel-link"/>
  96                 </link>
  97                 <description>
  98                     <xsl:value-of select="//user/biography"/>
  99                 </description>
 100                 <image>
 101                     <title>
 102                         <xsl:value-of select="$channel-title"/>
 103                     </title>
 104                     <link>
 105                         <xsl:value-of select="$channel-link"/>
 106                     </link>
 107                     <url>
 108                         <xsl:value-of select="//user/profile_pic_url"/>
 109                     </url>
 110                 </image>
 111                 <xsl:apply-templates select="//media/nodes/XML_Serializer_Tag"/>
 112             </channel>
 113         </rss>
 114     </xsl:template>
 115 </xsl:stylesheet>