rss_converter_dilbert.com.xsl

   1 <!--
   2   Stylesheet to convert Dilbert daily strips to RSS.
   3
   4   Copyright (C) 2013-2014  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <!--
  23   Since June 18, 2013 dilbert.com strips are not accessible anymore
  24   directly from the RSS feed, this message is displayed instead:
  25
  26     Dilbert readers - Please visit Dilbert.com to read this feature. Due
  27     to changes with our feeds, we are now making this RSS feed a link to
  28     Dilbert.com.
  29
  30   How unhandy is that, was it because of a management decision?
  31   Maybe a parody dilbert strip is needed about this issue...
  32 -->
  33
  34 <xsl:stylesheet version="1.0"
  35     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  36     xmlns:php="http://php.net/xsl"
  37     xsl:extension-element-prefixes="php"
  38     exclude-result-prefixes="php">
  39
  40     <xsl:output method="xml" indent="yes"/>
  41
  42     <xsl:variable name="BaseURL" select="//meta[@property='og:url']/@content"/>
  43
  44     <xsl:template match="//section[@class='comic-item']">
  45         <xsl:variable name="item-permalink" select=".//a[@class='img-comic-link']/@href"/>
  46         <xsl:variable name="picture-url" select=".//img[@class='img-responsive img-comic']/@src"/>
  47         <xsl:variable name="picture-title" select=".//img[@class='img-responsive img-comic']/@alt"/>
  48         <item>
  49             <title>
  50                 <xsl:variable name="title-length" select="140"/>
  51                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  52                 <xsl:choose>
  53                     <xsl:when test="string-length($picture-title) > $title-length">
  54                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  55                         <xsl:value-of select="substring($picture-title, 1, $truncated-length)"/>
  56                         <xsl:text>...</xsl:text>
  57                     </xsl:when>
  58                     <xsl:otherwise>
  59                         <xsl:value-of select="$picture-title"/>
  60                     </xsl:otherwise>
  61                 </xsl:choose>
  62             </title>
  63             <link>
  64                 <xsl:value-of select="$item-permalink"/>
  65             </link>
  66             <guid>
  67                 <xsl:value-of select="$item-permalink"/>
  68             </guid>
  69             <pubDate>
  70                 <xsl:value-of select="php:functionString('Tweeper::strToRssDate', normalize-space(.//date))"/>
  71             </pubDate>
  72             <description>
  73                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  74                 <img src="{$picture-url}" alt="{$picture-title}"/>
  75                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  76             </description>
  77         </item>
  78     </xsl:template>
  79
  80     <xsl:template match="/">
  81         <xsl:variable name="channel-title" select="//meta[@property='og:title']/@content"/>
  82         <xsl:variable name="channel-link" select="$BaseURL"/>
  83
  84         <rss version="2.0">
  85             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  86             <channel>
  87                 <generator>Tweeper</generator>
  88                 <title>
  89                     <xsl:value-of select="$channel-title"/>
  90                 </title>
  91                 <link>
  92                     <xsl:value-of select="$channel-link"/>
  93                 </link>
  94                 <description>
  95                     <xsl:value-of select="//meta[@property='og:description']/@content"/>
  96                 </description>
  97                 <image>
  98                     <title>
  99                         <xsl:value-of select="$channel-title"/>
 100                     </title>
 101                     <link>
 102                         <xsl:value-of select="$channel-link"/>
 103                     </link>
 104                     <url>
 105                         <xsl:value-of select="concat($BaseURL, //img[@alt='Dilbert logo']/@src)"/>
 106                     </url>
 107                 </image>
 108                 <xsl:apply-templates select="//section[@class='comic-item']"/>
 109             </channel>
 110         </rss>
 111     </xsl:template>
 112 </xsl:stylesheet>