src/rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015-2018  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:variable name="user-name" select="//ProfilePage/graphql/user/username"/>
  36
  37     <!--
  38          NOTE: some users do not specify the full name.
  39
  40          Remember to handle this case when using it and fall-back to the plain
  41          user name when appropriate.
  42     -->
  43     <xsl:variable name="full-name" select="//ProfilePage/graphql/user/full_name"/>
  44
  45     <xsl:variable name="location-name" select="//LocationsPage/graphql/location/name"/>
  46
  47     <xsl:variable name="hashtag-name" select="//TagPage/graphql/hashtag/name"/>
  48
  49     <xsl:variable name="screen-name">
  50         <xsl:choose>
  51             <xsl:when test="$location-name != ''">
  52                 <xsl:value-of select="$location-name"/>
  53             </xsl:when>
  54             <xsl:when test="$hashtag-name != ''">
  55                 <xsl:value-of select="$hashtag-name"/>
  56             </xsl:when>
  57             <xsl:when test="$full-name != ''">
  58                 <xsl:value-of select="$full-name"/>
  59             </xsl:when>
  60             <xsl:otherwise>
  61                 <xsl:value-of select="$user-name"/>
  62             </xsl:otherwise>
  63         </xsl:choose>
  64     </xsl:variable>
  65
  66     <xsl:template match="//edges/node">
  67         <xsl:variable name="item-content-image" select="./display_url"/>
  68         <xsl:variable name="item-content-caption" select="./edge_media_to_caption/edges/node/text"/>
  69         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./shortcode, '/')"/>
  70         <item>
  71             <title>
  72                 <xsl:variable name="title-length" select="140"/>
  73                 <xsl:variable name="item-content-title" select="normalize-space(concat($screen-name, ': ', $item-content-caption))"/>
  74                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  75                 <xsl:choose>
  76                     <xsl:when test="string-length($item-content-title) > $title-length">
  77                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  78                         <xsl:value-of select="substring($item-content-title, 1, $truncated-length)"/>
  79                         <xsl:text>...</xsl:text>
  80                     </xsl:when>
  81                     <xsl:otherwise>
  82                         <xsl:value-of select="$item-content-title"/>
  83                     </xsl:otherwise>
  84                 </xsl:choose>
  85             </title>
  86             <link>
  87                 <xsl:value-of select="$item-permalink"/>
  88             </link>
  89             <guid>
  90                 <xsl:value-of select="$item-permalink"/>
  91             </guid>
  92             <pubDate>
  93                 <xsl:variable name="timestamp" select="./taken_at_timestamp"/>
  94                 <xsl:value-of select="php:functionString('Tweeper\Tweeper::epochToRssDate', $timestamp)"/>
  95             </pubDate>
  96             <description>
  97                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  98                 <p>
  99                     <xsl:if test="./is_video/text() = 1">
 100                         (Video)
 101                     </xsl:if>
 102                     <xsl:value-of select="$item-content-caption"/>
 103                 </p><br />
 104                 <a href="{$item-permalink}"><img src="{$item-content-image}" style="max-width: 100%"/></a>
 105                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 106             </description>
 107             <xsl:if test="$generate-enclosure = 1">
 108                 <xsl:copy-of select="php:functionString('Tweeper\Tweeper::generateEnclosure', $item-content-image)"/>
 109             </xsl:if>
 110         </item>
 111     </xsl:template>
 112
 113     <xsl:template match="/">
 114
 115         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
 116         <xsl:variable name="channel-link">
 117             <xsl:choose>
 118                 <xsl:when test="$location-name != ''">
 119                     <xsl:variable name="location-id" select="//LocationsPage/graphql/location/id"/>
 120                     <xsl:value-of select="concat($BaseURL, '/explore/locations/', $location-id)"/>
 121                 </xsl:when>
 122                 <xsl:when test="$hashtag-name != ''">
 123                     <xsl:value-of select="concat($BaseURL, '/explore/tags/', $hashtag-name)"/>
 124                 </xsl:when>
 125                 <xsl:otherwise>
 126                     <xsl:value-of select="concat($BaseURL, '/', $user-name)"/>
 127                 </xsl:otherwise>
 128             </xsl:choose>
 129         </xsl:variable>
 130         <xsl:variable name="channel-image" select="//profile_pic_url"/>
 131
 132         <rss version="2.0">
 133             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
 134             <channel>
 135                 <generator>Tweeper</generator>
 136                 <title>
 137                     <xsl:value-of select="$channel-title"/>
 138                 </title>
 139                 <link>
 140                     <xsl:value-of select="$channel-link"/>
 141                 </link>
 142                 <description>
 143                     <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
 144                     <xsl:choose>
 145                         <xsl:when test="$location-name != ''">
 146                             <xsl:variable name="location-latitude" select="//LocationsPage/graphql/location/lat"/>
 147                             <xsl:variable name="location-longitude" select="//LocationsPage/graphql/location/lng"/>
 148                             <xsl:value-of select="concat($location-name, ' (', $location-latitude, ', ', $location-longitude, ')')"/>
 149                         </xsl:when>
 150                         <xsl:when test="$hashtag-name != ''">
 151                             <xsl:value-of select="concat('#', $hashtag-name)"/>
 152                         </xsl:when>
 153                         <xsl:otherwise>
 154                             <xsl:value-of select="normalize-space(concat($screen-name, '. ', //user/biography))"/>
 155                             <xsl:variable name="external-url" select="//user/external_url"/>
 156                             <xsl:if test="$external-url != ''">
 157                                 <xsl:text> </xsl:text><a href="{$external-url}"><xsl:value-of select="$external-url"/></a>
 158                             </xsl:if>
 159                         </xsl:otherwise>
 160                     </xsl:choose>
 161                     <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
 162                 </description>
 163                 <xsl:if test="$channel-image != ''">
 164                     <image>
 165                         <title>
 166                             <xsl:value-of select="$channel-title"/>
 167                         </title>
 168                         <link>
 169                             <xsl:value-of select="$channel-link"/>
 170                         </link>
 171                         <url>
 172                             <xsl:value-of select="$channel-image"/>
 173                         </url>
 174                     </image>
 175                 </xsl:if>
 176                 <xsl:apply-templates select="//ProfilePage/graphql/user/edge_owner_to_timeline_media/edges/node|//LocationsPage/graphql/location/edge_location_to_media/edges/node|//TagPage/graphql/hashtag/edge_hashtag_to_media/edges/node"/>
 177             </channel>
 178         </rss>
 179     </xsl:template>
 180 </xsl:stylesheet>