rss_converter_instagram.com.xsl

   1 <!--
   2   Stylesheet to convert Instagram user timelines to RSS.
   3
   4   Copyright (C) 2015  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generateEnclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://instagram.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:template match="display_src">
  36         <xsl:value-of disable-output-escaping="yes" select="php:function('Tweeper::generate_enclosure', string(text()))"/>
  37     </xsl:template>
  38
  39     <xsl:variable name="screen-name" select="//ProfilePage/XML_Serializer_Tag/user/full_name"/>
  40     <xsl:variable name="user-name" select="//ProfilePage/XML_Serializer_Tag/user/username"/>
  41
  42     <xsl:template match="//media/nodes/XML_Serializer_Tag">
  43         <xsl:variable name="item-content-image" select="./display_src"/>
  44         <xsl:variable name="item-content-caption" select="./caption"/>
  45         <xsl:variable name="item-permalink" select="concat($BaseURL, '/p/', ./code, '/')"/>
  46         <item>
  47             <title>
  48                 <xsl:variable name="title-length" select="140"/>
  49                 <!-- ellipsize, inspired from http://stackoverflow.com/questions/13622338 -->
  50                 <xsl:choose>
  51                     <xsl:when test="string-length($item-content-caption) > $title-length">
  52                         <xsl:variable name="truncated-length" select="$title-length - 3"/>
  53                         <xsl:value-of select="normalize-space(substring($item-content-caption, 1, $truncated-length))"/>
  54                         <xsl:text>...</xsl:text>
  55                     </xsl:when>
  56                     <xsl:otherwise>
  57                         <xsl:value-of select="normalize-space($item-content-caption)"/>
  58                     </xsl:otherwise>
  59                 </xsl:choose>
  60             </title>
  61             <link>
  62                 <xsl:value-of select="$item-permalink"/>
  63             </link>
  64             <guid>
  65                 <xsl:value-of select="$item-permalink"/>
  66             </guid>
  67             <pubDate>
  68                 <xsl:variable name="timestamp" select="./date"/>
  69                 <xsl:value-of select="php:functionString('Tweeper::epoch_to_gmdate', number($timestamp))"/>
  70             </pubDate>
  71             <description>
  72                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  73                 <p>
  74                     <xsl:if test="./is_video/text() = 1">
  75                         (Video)
  76                     </xsl:if>
  77                     <xsl:value-of select="$item-content-caption"/>
  78                 </p><br />
  79                 <a href="{$item-permalink}"><img src="{$item-content-image}" /></a>
  80                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  81             </description>
  82             <xsl:if test="$generateEnclosure = 1">
  83                 <xsl:apply-templates select="./display_src"/>
  84             </xsl:if>
  85         </item>
  86     </xsl:template>
  87
  88     <xsl:template match="/">
  89         <xsl:variable name="channel-title" select="concat('Instagram / ', $screen-name)"/>
  90         <xsl:variable name="channel-link" select="concat($BaseURL, //__path)"/>
  91
  92         <rss version="2.0">
  93             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  94             <channel>
  95                 <generator>Tweeper</generator>
  96                 <title>
  97                     <xsl:value-of select="$channel-title"/>
  98                 </title>
  99                 <link>
 100                     <xsl:value-of select="$channel-link"/>
 101                 </link>
 102                 <description>
 103                     <xsl:value-of select="//user/biography"/>
 104                 </description>
 105                 <image>
 106                     <title>
 107                         <xsl:value-of select="$channel-title"/>
 108                     </title>
 109                     <link>
 110                         <xsl:value-of select="$channel-link"/>
 111                     </link>
 112                     <url>
 113                         <xsl:value-of select="//user/profile_pic_url"/>
 114                     </url>
 115                 </image>
 116                 <xsl:apply-templates select="//media/nodes/XML_Serializer_Tag"/>
 117             </channel>
 118         </rss>
 119     </xsl:template>
 120 </xsl:stylesheet>