rss_converter_twitter.com.xsl

   1 <!--
   2   Stylesheet to convert Twitter user timelines to RSS.
   3
   4   Copyright (C) 2013-2014  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <xsl:stylesheet version="1.0"
  22     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  23     xmlns:php="http://php.net/xsl"
  24     xsl:extension-element-prefixes="php"
  25     exclude-result-prefixes="php">
  26
  27     <xsl:param name="generate-enclosure"/>
  28
  29     <xsl:output method="xml" indent="yes"/>
  30
  31     <xsl:variable name="BaseURL">
  32         <xsl:text>https://twitter.com</xsl:text>
  33     </xsl:variable>
  34
  35     <xsl:template match="a[@data-expanded-url]" mode="enclosure">
  36         <xsl:copy-of select="php:function('Tweeper::generateEnclosure', string(./@data-expanded-url))"/>
  37     </xsl:template>
  38
  39     <xsl:variable name="screen-name" select="//div[@class='user-actions btn-group not-following ']/@data-screen-name"/>
  40
  41     <xsl:template match="//li[@data-item-id and @data-item-type='tweet']">
  42         <xsl:variable name="user-name" select=".//div[contains(@class, 'js-stream-tweet')]/@data-screen-name"/>
  43         <xsl:variable name="item-content" select=".//p[contains(@class, 'js-tweet-text')]"/>
  44         <xsl:variable name="item-permalink" select="concat($BaseURL, .//div[@data-permalink-path]/@data-permalink-path)"/>
  45         <item>
  46             <title>
  47                 <xsl:value-of select="concat($user-name, ': ')"/>
  48                 <!--
  49                      Prepend a space in front of the URLs which are not
  50                      preceded by an open parenthesis, for aestethic reasons.
  51                      Also, regex, I know: http://xkcd.com/1171/
  52                 -->
  53                 <xsl:variable
  54                     name="processed-title"
  55                     select="php:function('preg_replace', '@((?&lt;!\()(?:http[s]?://|pic.twitter.com))@', ' \1', string($item-content))"/>
  56                 <!-- Also strip &nbsp; and &hellip; -->
  57                 <xsl:value-of select="normalize-space(translate($processed-title, '&#xA0;&#x2026;', ''))"/>
  58             </title>
  59             <link>
  60                 <xsl:value-of select="$item-permalink"/>
  61             </link>
  62             <guid>
  63                 <xsl:value-of select="$item-permalink"/>
  64             </guid>
  65             <pubDate>
  66                 <xsl:variable name="timestamp" select=".//span[contains(@class, 'js-short-timestamp')]/@data-time"/>
  67                 <xsl:value-of select="php:functionString('Tweeper::epochToRssDate', number($timestamp))"/>
  68             </pubDate>
  69             <description>
  70                 <xsl:value-of select="concat($user-name, ': ')"/>
  71                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  72                 <xsl:copy-of select="$item-content/node()"/>
  73                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  74             </description>
  75             <xsl:if test="$generate-enclosure = 1">
  76                 <xsl:apply-templates select="$item-content//a[@data-expanded-url]" mode="enclosure"/>
  77             </xsl:if>
  78         </item>
  79     </xsl:template>
  80
  81     <xsl:template match="/">
  82         <xsl:variable name="channel-title">
  83             <xsl:choose>
  84                 <xsl:when test="$screen-name != ''">
  85                     <xsl:value-of select="concat('Twitter / ', $screen-name)"/>
  86                 </xsl:when>
  87                 <xsl:otherwise>
  88                     <xsl:value-of select="concat('Twitter / ', normalize-space(//h1[1]))"/>
  89                 </xsl:otherwise>
  90             </xsl:choose>
  91         </xsl:variable>
  92         <xsl:variable name="channel-link" select="//link[@rel='canonical']/@href"/>
  93
  94         <rss version="2.0">
  95             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  96             <channel>
  97                 <generator>Tweeper</generator>
  98                 <title>
  99                     <xsl:value-of select="$channel-title"/>
 100                 </title>
 101                 <link>
 102                     <xsl:value-of select="$channel-link"/>
 103                 </link>
 104                 <description>
 105                     <xsl:value-of select="normalize-space(//div[@class='ProfileHeaderCard'])"/>
 106                 </description>
 107                 <image>
 108                     <title>
 109                         <xsl:value-of select="$channel-title"/>
 110                     </title>
 111                     <link>
 112                         <xsl:value-of select="$channel-link"/>
 113                     </link>
 114                     <url>
 115                         <xsl:value-of select="//a[contains(@class, 'profile-picture')]/@href"/>
 116                     </url>
 117                 </image>
 118                 <xsl:apply-templates select="//ol[@id='stream-items-id']/li[@data-item-id and @data-item-type='tweet']"/>
 119             </channel>
 120         </rss>
 121     </xsl:template>
 122 </xsl:stylesheet>