rss_converter_pump.io.xsl

   1 <!--
   2   Stylesheet to convert Pump.io activity streams to RSS.
   3
   4   Copyright (C) 2013-2014  Antonio Ospite <ao2@ao2.it>
   5
   6   This file is part of tweeper.
   7
   8   This program is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   This program is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21 <!-- To Evan, please reconsider publishing RSS ouput for _public_ contents -->
  22 <xsl:stylesheet version="1.0"
  23     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  24     xmlns:php="http://php.net/xsl"
  25     xsl:extension-element-prefixes="php">
  26
  27     <xsl:output method="xml" indent="yes"/>
  28
  29     <xsl:variable name="domain-name" select="substring-after(//div[@id='profile-block']/@data-profile-id, '@')"/>
  30     <xsl:variable name="BaseURL" select="concat('https://', $domain-name)"/>
  31
  32     <xsl:variable name="user-name" select="substring-after(//div[@id='profile-block']/@data-profile-id, ':')"/>
  33
  34     <xsl:template match="//div[@id='user-content-activities']//ul[@id='major-stream']/li">
  35         <xsl:variable name="activity-text" select=".//div[@class='activity-content']"/>
  36         <item>
  37             <title>
  38                 <xsl:value-of select="concat($user-name, ': ', normalize-space($activity-text))"/>
  39             </title>
  40             <link>
  41                 <xsl:value-of select=".//p[@class='muted']/small/a/@href"/>
  42             </link>
  43             <pubDate>
  44                 <xsl:value-of select="php:functionString('Tweeper::str_to_gmdate', .//abbr[@class='easydate']/@title)"/>
  45             </pubDate>
  46             <description>
  47                 <xsl:value-of select="concat($user-name, ': ')"/>
  48                 <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
  49                 <xsl:copy-of select="$activity-text/node()"/>
  50                 <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  51             </description>
  52         </item>
  53     </xsl:template>
  54
  55     <xsl:template match="/">
  56
  57         <rss version="2.0">
  58             <xsl:attribute name="xml:base"><xsl:value-of select="$BaseURL" /></xsl:attribute>
  59             <channel>
  60                 <generator>Tweeper</generator>
  61                 <title>
  62                     <xsl:value-of select="concat(substring-after($user-name, '@'), ' / ', substring-before($user-name, '@'))"/>
  63                 </title>
  64                 <link>
  65                     <xsl:value-of select="concat('https://', substring-after($user-name, '@'), '/', substring-before($user-name, '@'))"/>
  66                 </link>
  67                 <description>
  68                     <xsl:value-of select="normalize-space(//h1[@class='media-header'])"/>
  69                 </description>
  70                 <image>
  71                     <url>
  72                         <xsl:value-of select="//div[@id='profile-block']/span/img[@class='img-rounded media-object']/@src"/>
  73                     </url>
  74                 </image>
  75                 <xsl:apply-templates select="//div[@id='user-content-activities']//ul[@id='major-stream']/li"/>
  76             </channel>
  77         </rss>
  78     </xsl:template>
  79 </xsl:stylesheet>